From: "jamesk" <
[email protected]>
| D-D, i've read your posts here since i'm experiencing the same problem
| as the original poster.
| I have run the WMI Diag tool and it found NO errors, and both return
| codes came back as "success".
| So now i'm stumped as to what to do next.
| Doing a restore for me is not a very good option since i've just spent
| two days installing and setting up everything on this new pc, and
| absolutely can't remember at what point this problem started.
|
| Any advice/suggestions you or others here have would be great.
|
| --
| jamesk
I don't know if this will help in your case but, it is worth a try.
Create a FIXWMI.CMD batch file from the below script and run it and see if this corrects
your problem.
FIXWMI.CMD
------------------------
@echo on
cd /d c:\temp
if not exist %windir%\system32\wbem goto TryInstall
cd /d %windir%\system32\wbem
net stop winmgmt
winmgmt /kill
if exist Rep_bak rd Rep_bak /s /q
rename Repository Rep_bak
for %%i in (*.dll) do RegSvr32 -s %%i
for %%i in (*.exe) do call :FixSrv %%i
for %%i in (*.mof,*.mfl) do Mofcomp %%i
net start winmgmt
goto End
:FixSrv
if /I (%1) == (wbemcntl.exe) goto SkipSrv
if /I (%1) == (wbemtest.exe) goto SkipSrv
if /I (%1) == (mofcomp.exe) goto SkipSrv
%1 /RegServer
:SkipSrv
goto End
:TryInstall
if not exist wmicore.exe goto End
wmicore /s
net start winmgmt
:End