Where are non printing text effects in word 2007?

[Valerie]

Where are non printing text effect in word 2007? ie marching ants, etc.

 

[Graham Mayor]

They are no longer included with the font dialog, but can still be added by
macro e.g.

Sub AnimateFont()
Dim sAnimation As String
If Len(Selection.Range) = 0 Then
MsgBox "Select text first!", vbCritical, "No Text Selected"
Exit Sub
End If
sAnimation = InputBox("Which animation? Enter the number: " & vbCr & _
" 1. Blinking Background" & vbCr & _
" 2. Las Vegas Lights" & vbCr & _
" 3. Marching Black Ants" & vbCr & _
" 4. Marching Red Ants" & vbCr & _
" 5. Shimmer" & vbCr & _
" 6. Sparkle Text" & vbCr & _
" 0. None", "Font animation")
Select Case sAnimation
Case 1: Selection.Font.Animation = wdAnimationBlinkingBackground
Case 2: Selection.Font.Animation = wdAnimationLasVegasLights
Case 3: Selection.Font.Animation = wdAnimationMarchingBlackAnts
Case 4: Selection.Font.Animation = wdAnimationMarchingRedAnts
Case 5: Selection.Font.Animation = wdAnimationShimmer
Case 6: Selection.Font.Animation = wdAnimationSparkleText
Case 0: Selection.Font.Animation = wdAnimationNone
Case Else:
End Select
End Sub

http://www.gmayor.com/installing_macro.htm

--
<>>< ><<> ><<> <>>< ><<> <>>< <>><<>
Graham Mayor - Word MVP

My web site www.gmayor.com

<>>< ><<> ><<> <>>< ><<> <>>< <>><<>

 

[Pesach Shelniitz]

In previous versions of Word, you could select text, press Ctrl+D to open
the Font dialog box, click the Text Effects tab, and select one of the text
effects that you want to apply to the selected text. In Word 2007, the Text
Effects tab is not available, but you can still apply them to text by using
the following macro.

Sub TextEffects()
Dim animationType As String

animationType = InputBox("Type the name of a text effect." _
& vbCrLf & "Las Vegas lights" _
& vbCrLf & "Blinking background" _
& vbCrLf & "Sparkle text" _
& vbCrLf & "Marching black ants" _
& vbCrLf & "Marching red ants" _
& vbCrLf & "Shimmer" _
& vbCrLf & "None", _
"Text Effects")

With Selection.Font
Select Case animationType
Case "Las Vegas lights"
.Animation = wdAnimationLasVegasLights
Case "Blinking background"
.Animation = wdAnimationBlinkingBackground
Case "Sparkle text"
.Animation = wdAnimationSparkleText
Case "Marching black ants"
.Animation = wdAnimationMarchingBlackAnts
Case "Marching red ants"
.Animation = wdAnimationMarchingRedAnts
Case "Shimmer"
.Animation = wdAnimationShimmer
Case "None"
.Animation = wdAnimationNone
Case Else
MsgBox "No valid text effect was typed."
End Select
End With
End Sub

To install the macro, open the document in which you want to apply text
effects and perform the following steps.
1. If the Developer tab is not shown, click the Microsoft Office Button,
click Word Options, click Popular, and under Top options for working with
Word, select the Show Developer tab in the Ribbon check box.
2. Select the macro in this message and press Ctrl+C.
3. On the Developer tab, click Macros.
4. In the Macros dialog box, under Macro name, type the name of this macro
(Text Effects) and click Create.
5. In the Visual Basic Editor, select the short version of the macro that
was created and press Ctrl+V to replace it with the code that you copied
from this message.
6. Press Ctrl+S to save your changes and close (or minimize) the Visual
Basic Editor.

To run the macro, select some text in your document, open the Macros dialog
box as described in step 4 above or press Alt+F8, select the macro, and
click Run.

For more information about getting started using macros, see my Web page at
http://makeofficework.com/word_macros_the_benefits.htm.

Hope this helps,
Pesach Shelnitz