sending word doc through outlook - default fields

[CindyLu]

I have a document (which someone else set up originally) that I e-mail to the
same address on a regular basis. Inside Word, I click on File/Send To/

It has always opened up with the proper address in the "send to" box and the
proper heading.

Yesterday the IT guys had to re-install my Microsoft Office (don't ask... it
was ugly!) No my default fields ar blank.

How do I recreate them so they will be there every time I send the document?

 

[Graham Mayor]

Presumably you had a macro in normal.dot which your IT guys have replaced
when they re-installed Office. Re-installing Office rarely achieves anything
useful, and normal.dot when replaced should be replaced by renaming and not
by deleting, to avoid situations like this. Your IT department needs a kick.
Ask them for the backup of normal.dot that they took before deleting it

In the meantime I don't know anything about your document, but the following
macro will send the document, using Outlook, to the indicated e-mail address
as an attachment. Add the macro to a toolbar button -
http://www.gmayor.com/installing_macro.htm

Sub SendDocumentAsAttachment()
Dim bStarted As Boolean
Dim oOutlookApp As Outlook.Application
Dim oItem As Outlook.MailItem
On Error Resume Next
If Len(ActiveDocument.Path) = 0 Then 'Document has not been saved
ActiveDocument.Save 'so save it
End If
'see if Outlook is running and if so turn your attention there
Set oOutlookApp = GetObject(, "Outlook.Application")
If Err <> 0 Then 'Outlook isn't running
'So fire it up
Set oOutlookApp = CreateObject("Outlook.Application")
bStarted = True
End If
'Open a new e-mail message
Set oItem = oOutlookApp.CreateItem(olMailItem)
With oItem 'and add the detail to it
.To = "(e-mail address removed)" 'send to this address
.Subject = "New subject" 'This is the message subject
.Body = "See attached document" ' This is the message body text
.Attachments.Add Source:=ActiveDocument.FullName, Type:=olByValue
.Send
'**********************************
'If you want to view the message before it goes
'change the line above from .Send to .Display
'Otherwise the message is sent straight to the Outbox
'and if you have Outlook set to send mail immediately, it will simply be
sent
'with no obvious sign that Outlook has operated.
'Apart from the copy in the Outlook Sent folder
'**********************************
End With
If bStarted Then 'If the macro started Outlook, stop it again.
oOutlookApp.Quit
End If
'Clean up
Set oItem = Nothing
Set oOutlookApp = Nothing
End Sub

--
<>>< ><<> ><<> <>>< ><<> <>>< <>><<>
Graham Mayor - Word MVP

My web site www.gmayor.com

<>>< ><<> ><<> <>>< ><<> <>>< <>><<>