Add Signature Automatically in MS Word -- File Send as Attachment

[Carol Creagan]

I have a user who wants his signature to insert automatically when he sends a
Word Document using Word's -- File Send to -- As Attachment. The user has
his signature set to automatically appear on all new email messages as well
as any replies or items he forwards.

Is there a way to have the other MS applications read the default signature
options from Outlook when sending email from these applications.

Our current Mail format is HTML but I have also tried using Word as the
email editor and that didn't make a difference. Any help would be
appreciated.

 

[MeghanC]

I had the same problem, and came across this. It works for my system!

~Meghan


You could do it with a macro in the normal template e.g. as follows, which will use the signature associated with the active e-mail account. Note that this macro uses early binding to the Outlook object library so you will need to set a reference to that library in the vba editor - tools > references - see http://www.gmayor.com/installing_macro.htm

Sub Send_As_Mail_Attachment()

' send the document as an attachment _
in an Outlook Email message
Dim bStarted As Boolean
Dim oOutlookApp As Outlook.Application
Dim oItem As Outlook.MailItem

On Error Resume Next

'Prompt the user to save the document
ActiveDocument.Save

'Get Outlook if it's running
Set oOutlookApp = GetObject(, "Outlook.Application")

'Outlook wasn't running, start it from code
If Err <> 0 Then
Set oOutlookApp = CreateObject("Outlook.Application")
bStarted = True
End If

'Create a new mailitem
Set oItem = oOutlookApp.CreateItem(olMailItem)

With oItem
' .to = "someonerATsomewhere.com" 'the recipient (optional)
' .Subject = "This is the subject" 'the subject (optional)
'Add the document as an attachment
.Attachments.Add Source:=ActiveDocument.FullName, _
Type:=olByValue, DisplayName:="Document as attachment"
.Display
End With

'Clean up
Set oItem = Nothing
Set oOutlookApp = Nothing
End Sub