To implement the second option you would have to recreate all your templates
using includetext and/or includepicture fields in place of the address and
logo . It is not worth the hassle unless you change address often. If the
templates all use the same header information, it is probably still simpler
to batch replace the old header address with the new one.It would be easy
enough to modify the macro to target the information specifically.
If starting again from scratch, then I would also consider using docvariable
fields to display the address information, but again you would need to use a
macro to batch update the templates to change the content of the
docvariables. eg the following macro will update the docvariable fields
{DocVariable varAddress} and {DocVariable varPhone} with the new information
gathered from the macro. Actually it wouldn't be that much more difficult to
replace the address with the docvariable fields by macro also.
Sub BatchProcess()
Dim strFilename As String
Dim strPath As String
Dim oDoc As Document
Dim fDialog As FileDialog
Dim sAddr1 As String
Dim sAddr2 As String
Dim sAddr3 As String
Dim sAddr4 As String
Dim sPhone As String
sAddr1 = InputBox("Address Line 1?")
sAddr2 = InputBox("Address Line 2?")
sAddr3 = InputBox("Address Line 3?")
sAddr4 = InputBox("Address Line 4?")
sPhone = InputBox("Phone Number?")
Set fDialog = Application.FileDialog(msoFileDialogFolderPicker)
With fDialog
.Title = "Select folder and click OK"
.AllowMultiSelect = False
.InitialView = msoFileDialogViewList
If .Show <> -1 Then
MsgBox "Cancelled By User", , _
"List Folder Contents"
Exit Sub
End If
strPath = fDialog.SelectedItems.Item(1)
If Right(strPath, 1) <> "\" _
Then strPath = strPath + "\"
End With
If Documents.Count > 0 Then
Documents.Close SaveChanges:=wdPromptToSaveChanges
End If
If Left(strPath, 1) = Chr(34) Then
strPath = Mid(strPath, 2, Len(strPath) - 2)
End If
strFilename = Dir$(strPath & "*.dot")
While Len(strFilename) <> 0
Set oDoc = Documents.Open(strPath & strFilename)
'
'Do what you want with oDoc e.g.
oDoc.Variables("varAddress").Value = sAddr1 & Chr(13) & _
sAddr2 & Chr(13) & sAddr3 & Chr(13) & sAddr4
oDoc.Variables("varPhone").Value = sPhone
oDoc.Fields.Update
'
oDoc.Close SaveChanges:=wdSaveChanges
strFilename = Dir$()
Wend
End Sub
--
<>>< ><<> ><<> <>>< ><<> <>>< <>><<>
Graham Mayor - Word MVP
My web site
www.gmayor.com
<>>< ><<> ><<> <>>< ><<> <>>< <>><<>
Thank you for suggestion.
In order to your first suggestion I should be able to change this
macro to work properly, but I don't fully understand your second one.
Replace it with bookmarked section? What do you mean exactly? How can
I do this?
How about new templates? I will have to create 15 new contracts and
again with different content and the same Header and Footer. Is there
a way to create new files with capability to changing Headers and
Footers automatic in all those new files?
Best regards,
BD.
