Permanently merge cells with text data w/o a formula?

[Guest]

Is it possible to combine the text entrys of multiple cells (in the same
column) without the use of a formula?

For example, I have data in C5, C6, and C7, I would highlight those cells
and...?

Thanks in advance,

-Chris

 

[Gord Dibben]

Not without a formula or a VBA macro.


Gord Dibben MS Excel MVP

 

[Guest]

Gord,

Any thoughts on a macro I could create to make this happen?

Thanks,

-Chris

 

[Gord Dibben]

Couple of ways to go.

Function ConCatRange(CellBlock As Range) As String
Dim cell As Range
Dim sbuf As String
For Each cell In CellBlock
If Len(cell.text) > 0 Then sbuf = sbuf & cell.text & " "
Next
ConCatRange = Left(sbuf, Len(sbuf) - 1)
End Function

=ConCatRange(C5:C7) which gives you space-delimited list of a contiguous range.

Or a macro which allows a de-limiter and non-contiguous cells to be chosen.

Sub ConCat_Cells()
Dim x As Range
Dim y As Range
Dim z As Range
Dim w As String
Dim sbuf As String
On Error GoTo endit
w = InputBox("Enter the Type of De-limiter Desired")
Set z = Application.InputBox("Select Destination Cell", _
"Destination Cell", , , , , , 8)
Application.SendKeys "+{F8}"
Set x = Application.InputBox("Select Cells...Contiguous or Non-Contiguous", _
"Cells Selection", , , , , , 8)
For Each y In x
If Len(y.text) > 0 Then sbuf = sbuf & y.text & w
Next
z = Left(sbuf, Len(sbuf) - 1)
Exit Sub
endit:
MsgBox "Nothing Selected. Please try again."
End Sub


Gord

 

[Guest]

Cheers.

Thanks,

-Chris