Nesting IF Statements

[Gaz]

How do I nest this together?


If A1 = 0 & B1 =0, "OK"

If A1 >0 & B1 = 0, "No B"

If A1 = 0 & B1 >0, "No A"

If A1 >0 & B1 >0, "OK"


cheers

Gaz

 

[Fred Smith]

Try:
=if(and(a1=0,b1=0),"OK",if(and(a1>0,b1=0),"No B",if(and(a1=0,b1>0),"No
A",if(and(a1>0,b1>0),"OK","None of the above"))))

Regards,
Fred

 

[CB]

Try:
=IF(B1>0,IF(A1=0,"No A","OK"),IF(A1>0,IF(B1=0,"No B","OK"),"OK"))

 

[Joe User]

How do I nest this together?
If A1 = 0 & B1 =0, "OK"
If A1 >0 & B1 = 0, "No B"
If A1 = 0 & B1 >0, "No A"
If A1 >0 & B1 >0, "OK"

=if(and(A1>0,B1=0), "No B",
if(and(A1=0,B1>0), "No A", "OK"))

If A1 and B1 may be negative, then:

=if(and(A1<>0,B1=0), "No B",
if(and(A1=0,B1<>0), "No A", "OK"))

 

[Ron Rosenfeld]

How do I nest this together?


If A1 = 0 & B1 =0, "OK"

If A1 >0 & B1 = 0, "No B"

If A1 = 0 & B1 >0, "No A"

If A1 >0 & B1 >0, "OK"


cheers

Gaz

And a little different approach, just for kicks:

=CHOOSE(1+BIN2DEC(--(A1>0) & --(B1>0)),"OK","No A","No B","OK")

--ron

 

[Ron Rosenfeld]

How do I nest this together?


If A1 = 0 & B1 =0, "OK"

If A1 >0 & B1 = 0, "No B"

If A1 = 0 & B1 >0, "No A"

If A1 >0 & B1 >0, "OK"


cheers

Gaz

And still another approach:

=INDEX({"OK","No A","No B","OK"},1+(A1>0)*2+(B1>0))

--ron

 

[Gaz]

Thanks for the responses, now have what I need - much appreciated

cheers

Gaz