Multiple Criteria in Sum if Formula

[naveeenc]

Hi,
How to put multiple Criterias in Sum if formula???

If the data in A1 & B1 matches as per the criteria, it should add Cell C1...

 

[T. Valko]

If the data in A1 & B1 matches as per the criteria

It would have been better if you told us what the criteria are.

Try something like this:

=SUMPRODUCT(--(A1:A10="criteria1"),--(B1:B10="criteria2"),C1:C10)

Better to use cells to hold the criteria:

E1 = criteria1
F1 = criteria2

=SUMPRODUCT(--(A1:A10=E1),--(B1:B10=F1),C1:C10)

If you're using Excel 2007:

=SUMIFS(C1:C10,A1:A10,"criteria1",B1:B10,"criteria2")

=SUMIFS(C1:C10,A1:A10,E1,B1:B10,F1)

In all of the above formulas if criteriaN is a NUMBER then don't use the
quotes.

=SUMPRODUCT(--(A1:A10=10),--(B1:B10=0),C1:C10)

 

[Ms-Exl-Learner]

Try this…

If you want only to show C1 value when A1 & B1 values are matching then use
this formula
=IF(OR(A1="",B1=""),"",IF(A1=B1,C1,"A1 & B1 IS NOT MATCHING"))

If you want to sum A1 to C1 when a1 & b1 values are matching then use this
formula
=IF(OR(A1="",B1=""),"",IF(A1=B1,SUM(A1:C1),"A1 & B1 IS NOT MATCHING"))

If this post helps, Click Yes!