If/Then Formulas

[Bk Goto]

Hello and Good Day =)

I am in need of some help...

I would like to create a formula where
IF cell F7 =1 then E7*1, IF F7=2 then E7*1, IF F7=3, then E7*2

Any help would be appreciated, I know it can be done, but haven't a clue as
to how ;-)

Thanx ~ Bkg.

 

[Mike H]

How about without an if formula

=CHOOSE(F7,E7*1,E7*1,E7*2)

Mike

 

[Gary Brown]

=IF(OR(F7=1,F7=2),E7*1,E7*2)

 

[Glenn]

Hello and Good Day =)

I am in need of some help...

I would like to create a formula where
IF cell F7 =1 then E7*1, IF F7=2 then E7*1, IF F7=3, then E7*2

Any help would be appreciated, I know it can be done, but haven't a clue as
to how ;-)

Thanx ~ Bkg.

=IF(OR(F7=1,F7=2),E7,IF(F7=3,E7*2,"F7 is not 1, 2 or 3"))

 

[Per Jessen]

Hi

=IF(F7=1,E7*1,IF(F7=2,E7*1,IF(F7=3,E7*2,"")))

Regards,
Per

 

[Rick Rothstein \(MVP - VB\)]

Yet another method...

=E7*LOOKUP(F7,{1,2,3},{1,1,2})

Rick

 

[Bk Goto]

You are the best!! I knew XL could do it, but I am self taught, and never
had the need for such a formula.

THANK YOU THANK YOU THANK YOU!!!!

 

[Lars-Åke Aspelin]

Hello and Good Day =)

I am in need of some help...

I would like to create a formula where
IF cell F7 =1 then E7*1, IF F7=2 then E7*1, IF F7=3, then E7*2

Any help would be appreciated, I know it can be done, but haven't a clue as
to how ;-)

Thanx ~ Bkg.

Just to add another formula to the collection you have already got:

=E7*(4-3*F7+F7*F7)/2

Shortest so far I guess, but also the least recommended to use because
it is difficult to see through and hard to update when the
requirements change.

Lars-Åke

 

[Lars-Åke Aspelin]

Just to add another formula to the collection you have already got:

=E7*(4-3*F7+F7*F7)/2

Shortest so far I guess, but also the least recommended to use because
it is difficult to see through and hard to update when the
requirements change.

Lars-Åke

Even shorter

=E7*(4-3*F7+F7^2)/2

Lars-Åke

 

[Rick Rothstein \(MVP - VB\)]

And even shorter yet<g>...

=E7*(1+INT(F7/3))

Rick

 

[Mike H]

I suspect the OP didn't want to broaden his/her horizons beyond IF

=E7*(4-3*F7+F7^2)/2

Nice

Mike

 

[Rick Rothstein \(MVP - VB\)]

And even shorter than that...

=E7*INT(1+F7/3)

Rick

 

[Mike H]

I think we have a winner

And even shorter yet<g>...

=E7*(1+INT(F7/3))

Rick

 

[Teethless mama]

Think again...This one even shorter than Rick.R

=((F7=3)+1)*E7

 

[Rick Rothstein \(MVP - VB\)]

Nice! Not only is it one shorter than mine... it uses no function calls
either.

Rick

 

[Rick Rothstein \(MVP - VB\)]

LOL... you are going to kick yourself for missing this! One character
shorter...

=E7*(F7=3)+E7

Rick

 

[Rick Rothstein \(MVP - VB\)]

Of course, it is only shorter as long as the Column E address is an address
composed of 2 characters (in the range A1:Z9). If the address is 3
characters long, then the formulas are the same length; and, if the address
is 4 or more characters long, then your form of the formula will be shorter.

Rick

 

[John C]

And if F7 contains no data, every one of these 'shorter solutions' is
incorrect. I will even allow that there is DV allowing only whole numbers
from 1 to 3, but until F7 is populated, every formula will have some output
that will be incorrect.

 

[John C]

And of course, stealing from Ricks' formula:
=E7*(F7=3)+E7*(F7={1,2,3})

 

[John C]

No, mine failed too
--
John C

And of course, stealing from Ricks' formula:
=E7*(F7=3)+E7*(F7={1,2,3})