IF(AND with date comparison

[PSU35]

I have an =IF(AND( .... formula. One of the conditions in the AND portion is
to compare a date in one cell(call it sht-1 A1) with the dates in 2 other
cells (call them sht-2, A1 and A2, one being a start date and the other a
finish date). I am trying to return a "FALSE " if the sht-1 date falls
outside (either before or after) of the dates in sht-2 cells.

The formula as written is:
=IF(AND($B9>0,$D9>0,$E9="yes",N$8>='Proposal Data'!$C$7,'Proposal
Data'!$C$11>=N$8)...............................

The portion that isn't working is the 4th argument where N8 is compared to
the other dates in C7 and C11. It is returning a "TRUE" when no dates are
present in C7 & C11 and allowing the remaining calculations to ocurr. There
is more to the formula but it is just additional IF statements. Can someone
tell me what i am doing wrong? By the way, when dates are present in C7 &
C11 the formula works perfectly.

 

[Jacob Skaria]

The below returns true if the date in N8 is between the dates in c7 and c11..

=IF(COUNT('Proposal Data'!$C$7,'Proposal Data'!$C$11)=2,MEDIAN('Proposal
Data'!$C$7,'Proposal Data'!$C$11,N$8)=N8)


If this post helps click Yes

 

[muddan madhu]

AND($B9>0,$D9>0,$E9="yes",N$8>=$C$7,$C$11>=N$8,AND(C7>0,C11>0))

 

[T. Valko]

N$8>='Proposal Data'!$C$7,'Proposal Data'!$C$11>=N$8

The only way that could be TRUE is if there are certain combinations of
numbers and/or TEXT in the 3 cells.

Maybe try adding a condition that tests all 3 cells are numeric:

AND(COUNT(N$8,'Proposal Data'!$C$7,'Proposal Data'!$C$11)=3,N$8>='Proposal
Data'!$C$7,'Proposal Data'!$C$11>=N$8)

 

[PSU35]

Thank you...you simple solution worked wonderfully.
Many thanks.
Rick