how to get rid of ’

[Earl]

I have a problem with ( ’) showing up in documents. Here is where it occurs:

In Microsoft Word, the apostrophe is displayed as a circle with an inward
leaning hook on the right side. Open Microsoft word and enlarge an apostrophe
to see an apostrophe displayed.

The problem occurs when a document in Microsoft word is copied & pasted into
another application. Instead of displaying the apostrophe correctly, the
apostrophe is displayed as this character: ( ’ ) For example in the
contraction: don't, is instead displayed as don’t.

If you noticed in the body of this document, the apostrophe is displayed as
a small mark ( ' ), not the full circle & hook as used in Microsoft Word.

The question is how do I change, within Microsoft Word, the apostrophe to be
displayed as a simple mark ( ' ) and not the full circle & hook default
Microsoft Word uses?

Or is there any other way to display an apostrophe correctly, and not the (
’ ) when copying & pasting from Microsoft Word?

Thanks for any suggestions

 

[Graham Mayor]

You are using the autoformat as you type option to change straight quotes to
smart quotes and the application you are pasting into cannot handle the
smart quotes. Turn off the autoformat as you type option. Tools >
autocorrect > autoformat as you type or in 2007 Word Options > proofing >
autocorrect options > autoformat as you type.

If you want to keep the smart quotes option for the benefit of your Word
documents, ignore the above and run the following macro before copying to
the other application

Sub ReplaceQuotes()
Dim vFindText As Variant
Dim vReplText As Variant
Dim sFormat As Boolean
Dim i As Long
sFormat = Options.AutoFormatAsYouTypeReplaceQuotes
vFindText = Array(Chr(147), Chr(148), Chr(145), Chr(146))
vReplText = Array(Chr(34), Chr(34), Chr(39), Chr(39))
Options.AutoFormatAsYouTypeReplaceQuotes = False
Selection.HomeKey wdStory
With Selection.Find
.Forward = True
.Wrap = wdFindContinue
.MatchWholeWord = True
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
.Format = True
.MatchCase = True

For i = LBound(vFindText) To UBound(vFindText)
.Text = vFindText(i)
.Replacement.Text = vReplText(i)
.Execute Replace:=wdReplaceAll
Next i
End With
Options.AutoFormatAsYouTypeReplaceQuotes = sFormat
End Sub

http://www.gmayor.com/installing_macro.htm

--
<>>< ><<> ><<> <>>< ><<> <>>< <>><<>
Graham Mayor - Word MVP

My web site www.gmayor.com

<>>< ><<> ><<> <>>< ><<> <>>< <>><<>

 

[grammatim]

Turn off the option "Replace Straight Quotes with Smart Quotes" in the
Autoformat and/or Autoformat As You Type areas.

(Even though the "smart quotes" or "curly quotes" are greatly
preferred in typeset documents.)

Note that between the parentheses in your message I see space--a-
circumflex--euro--trademark.