highlight row of active cell

[pswanie]

Hi all

i got a sheet where the user use only column m down. but i want the row of
the active cell to be hightlight.

in other words if a user select m12 i want the row m12 to be highlighted
automatic. The reason for this is that they need to easily see that they
are in the row with the right product in colum b down



Column b down will have the product name and in m they need to enter amount
of product to order. i cant hide the other columns as there are info in
that help them make the order....

regards


Phillip

 

[Don Guillett]

Here's one by Bob Phillips. Right click sheet tab>view code>insert this.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Cells.FormatConditions.Delete
With Target.EntireRow
.FormatConditions.Add Type:=xlExpression, Formula1:="TRUE"
With .FormatConditions(1)
With .Borders(xlTop)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = 5
End With
With .Borders(xlBottom)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = 5
End With
End With
.FormatConditions(1).Interior.ColorIndex = 20
End With

End Sub

 

[FSt1]

hi
see if this is what you want....
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim r As Range
Set r = Range("M:M")
If Not Intersect(Target, r) Is Nothing Then
ActiveCell.EntireRow.Select
End If
End Sub

this is worksheet code. right click the sheet tab and from the popup, click
view code. paste the above into the code window. test it.

regards
FSt1

 

[Gord Dibben]

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Static OldCell As Range
If Target.Column <> 13 Then Exit Sub
If Application.CutCopyMode = 0 Then
If Not OldCell Is Nothing Then
OldCell.EntireRow.Interior.ColorIndex = xlColorIndexNone
OldCell.EntireRow.Borders.LineStyle = xlLineStyleNone
End If
Set OldCell = Target
OldCell.EntireRow.Interior.ColorIndex = 6
OldCell.EntireRow.Borders.LineStyle = xlContinuous
Else
If OldCell Is Nothing Then
Set OldCell = Target
Else
Set OldCell = Union(OldCell, Target)
End If
End If
End Sub

Right-click on the sheet tab and "View Code".

Copy/paste the code into that module.

Alt + q to return to Excel.


Gord Dibben MS Excel MVP

 

[Rick Rothstein]

Give this Worksheet Change event code a try...

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
On Error GoTo Whoops
Application.ScreenUpdating = False
Cells.Borders.LineStyle = xlLineStyleNone
If Intersect(Target, Columns("M")) Is Nothing Then Exit Sub
Target.EntireRow.BorderAround Weight:=xlMedium
Whoops:
Application.ScreenUpdating = True
End Sub

 

[Rick Rothstein]

Of course I should have said "Give this SelectionChange event code a try"
(note that I inadvertently typed "Change event" in my original post).

--
Rick (MVP - Excel)

Give this Worksheet Change event code a try...

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
On Error GoTo Whoops
Application.ScreenUpdating = False
Cells.Borders.LineStyle = xlLineStyleNone
If Intersect(Target, Columns("M")) Is Nothing Then Exit Sub
Target.EntireRow.BorderAround Weight:=xlMedium
Whoops:
Application.ScreenUpdating = True
End Sub

 

[pswanie]

Sorry for not getting back yet...

Had to leave office unexpectedly quick. wil try the codes on Friday and
will flag the posts then...

Thanx inadvance