Complex Match

[Vic]

I have 2 sheets. I need to compare F92 of Sheet-1 with Sheet-2 range from
F21:F9300. If there is a match then I need to see corresponding value in cell
I of sheet-2. If that value is X or R, then on Sheet-1, next to F92 I need to
insert Yes into G92. I need to check Sheet-1 F92 thru F1893. As a result, I
will see some "Yes" in column G of sheet-1.
How can I do this?
Thank you.

 

[Jacob Skaria]

Try the below formula in sheet1 G92

=IF(ISNA(MATCH(F92,Sheet2!F21:F9300,0)),"",
IF(OR(INDEX(Sheet2!I21:I9300,MATCH(F92,Sheet2!F21:F9300,0))="x",
INDEX(Sheet2!I21:I9300,MATCH(F92,Sheet2!F21:F9300,0))="R"),
"Yes",""))

If this post helps click Yes

 

[Vic]

When I copy this cell down, it changes all numbers. Therefore the last G1893
looks like this
=IF(ISNA(MATCH(F1893,'DCF-PRA'!F1822:F11101,0)),"",IF(OR(INDEX('DCF-PRA'!I1822:I11101,MATCH(F1893,'DCF-PRA'!F1822:F11101,0))="x",INDEX('DCF-PRA'!I1822:I11101,MATCH(F1893,'DCF-PRA'!F1822:F11101,0))="R"),"Yes",""))
I need to keep the range from 21 to 9300 from Sheet-2. How do I fix this?

 

[Jacob Skaria]

Use absolute referencing. Below are the different reference styles.
A1 Relative referencing. Both column and row will change if you copy or drag
the formula.
$A1 The column reference is fixed and will not change
A$1 The row reference is fixed and will not change.
$A$1 Column and row reference are fixed.

=IF(ISNA(MATCH(F92,Sheet2!$F$21:$F$9300,0)),"",
IF(OR(INDEX(Sheet2!$I$21:$I$9300,MATCH(F92,Sheet2!$F$21:$F$9300,0))="x",
INDEX(Sheet2!$I$21:$I$9300,MATCH(F92,Sheet2!$F$21:$F$9300,0))="R"),
"Yes",""))

If this post helps click Yes

 

[Vic]

Dear Jacob,
I have another complication. "Yes" was not sufficient enough. In case of a
match, I need to put corresponding value of cell K from Sheet2 into F92. How
can I do that?
I tried Sheet2!K21 instead of "Yes" but that did not work.
Thank you.