Add values in "P" that fall between dates "03/01/00 and 03/31/00"

[Art]

A B E
2 01/11/2009 214 $140,000
3 01/25/2009 309 $40,000
4 03/03/2009 309 $200,000
5 03/15/2009 214 $10,000
6 03/21/2009 309 $300,000
7 03/25/2009 309 $120,000
8 04/15/2009 309 $150,000

Hello,

I am hoping someone is able to help me with this issue. I am attempting to
sum the values in a column, "E" when the date in column, "A" falls between
03/01/2009 and 03/31/2009, and the number in column "B" is equal to "309".
Using the data above the formula should only add rows, 4, 6, & 7 for a total
of
$620,000. I have had a time of it trying to figure out how to create a to do
this. Can anyone please assit?

 

[macropod]

Hi Art,

Try:
=SUMPRODUCT((A2:A8>=DATEVALUE("01/03/2009"))*(A2:A8<DATEVALUE("31/03/2009"))*(B2:B8=309),E2:E8)

 

[macropod]

Oops - with your regional settings, that should be:
=SUMPRODUCT((A2:A8>=DATEVALUE("03/01/2009"))*(A2:A8<DATEVALUE("03/31/2009"))*(B2:B8=309),E2:E8)

 

[JBeaucaire]

Give this a try:

=SUMPRODUCT(--(DATE(YEAR($A$2:$A$8),
MONTH($A$2:$A$8),1)=DATE(2009,3,1)),
--($B$2:$B$8=309),E2:E8)

 

[T. Valko]

Try one of these...

Use cells to hold your criteria:

G2 = start date
H2 = end date
I2 = 309

=SUMPRODUCT(--(A2:A8>=G2),--(A2:A8<=H2),--(B2:B8=I2),E2:E8)

If you're using Excel 2007:

=SUMIFS(E2:E8,A2:A8,">="&G2,A2:A8,"<="&H2,B2:B8,I2)

 

[Art]

Thank you very much. This is simple to follow and works like a charm. Thank
you to everyone who posted a response. I appreciate your assistance.
"DATEVALUE" was the key. Thank you.
--
Art
Los Angeles, California

Oops - with your regional settings, that should be:
=SUMPRODUCT((A2:A8>=DATEVALUE("03/01/2009"))*(A2:A8<DATEVALUE("03/31/2009"))*(B2:B8=309),E2:E8)

 

[macropod]

Hi Art,

You're welcome.

In the case of the formula I submitted, you might want to change '<' to '<=' if the intention is to include the end date in the
range, or to change '>=' to '>' if the intention is to exclude the start date from the range. It all comes down to what you meant by
'between'.

--
Cheers
macropod
[MVP - Microsoft Word]

Thank you very much. This is simple to follow and works like a charm. Thank
you to everyone who posted a response. I appreciate your assistance.
"DATEVALUE" was the key. Thank you.
--
Art
Los Angeles, California

Oops - with your regional settings, that should be:
=SUMPRODUCT((A2:A8>=DATEVALUE("03/01/2009"))*(A2:A8<DATEVALUE("03/31/2009"))*(B2:B8=309),E2:E8)

--
Cheers
macropod
[MVP - Microsoft Word]

A B E
2 01/11/2009 214 $140,000
3 01/25/2009 309 $40,000
4 03/03/2009 309 $200,000
5 03/15/2009 214 $10,000
6 03/21/2009 309 $300,000
7 03/25/2009 309 $120,000
8 04/15/2009 309 $150,000

Hello,

I am hoping someone is able to help me with this issue. I am attempting to
sum the values in a column, "E" when the date in column, "A" falls between
03/01/2009 and 03/31/2009, and the number in column "B" is equal to "309".
Using the data above the formula should only add rows, 4, 6, & 7 for a total
of
$620,000. I have had a time of it trying to figure out how to create a to do
this. Can anyone please assit?