Vlookup Please Help

[Guest]

I have data in column C for several days. Some of the data is repeated. I
only need the data out of here that does not have a duplicate. I was told you
could do this with vlookup. Can someone help? Thanks

 

[Don Guillett]

try data>filter>advanced filter>unique

 

[Guest]

I have data in column C for several days. Some of the data is repeated. I
only need the data out of here that does not have a duplicate. I was told you
could do this with vlookup. Can someone help? Thanks

One way to dynamically* extract the uniques into an adjacent col ..

Assuming source data in col C,
from row1 down to say, an expected max row100

In D1:
=IF(ISERROR(SMALL(E:E,ROW())),"",INDEX(C:C,MATCH(SMALL(E:E,ROW()),E:E,0)))

In E1:
=IF(C1="","",IF(COUNTIF($C$1:C1,C1)>1,"",ROW()))

Select D1:E1, copy down to E100
(cover the max expected extent of data in col C)

The unique items in col C will be auto-extracted into col D,
all results neatly bunched at the top.

(Hide away the criteria col E, if desired)

*If it's a one-off run, we could also:

Select col C
Click Data > Filter > Advanced Filter
Check: Copy to another location,
Copy to: F1 (say)
Check "Unique records only"
Click OK
(Unique items will be listed in col F)


---

 

[Guest]

Just another fine angle to it, focusing on your line:
The preceding methods suggested will yield the uniques list of items in col
C, which include the 1st instances of items having duplicates, i.e. repeated
elsewhere down the col.

If what you're really after is only the items in col C w/o any duplicate(s)
then we could just replace the formula in col E with

In E1:
=IF(C1="","",IF(COUNTIF(C:C,C1)=1,ROW(),""))
E1 copied down to E100, as before

(No change to the formulas in col D)

Col D will then return the desired results

Note that we can't use: Advanced Filter > Uniques
to drive out the above interp

---