Using API with VBA in Excel

R

rahela

I need to get into an excel worksheet the results of a dir
function, (including sub directories), so that on the first coloumn
let say A will be the directory (including the sub directories),
on coloumn B the file name, and on coloumn C the file extention,
on coloumn D the file size and coloumn E the date the file was
changed.
My OS is windows XP and my excel ver is 2000.
The type of files should not include hidden files of system files
:)

Thanks for the help
rahel
 
B

Bob Phillips

Frank,

That solution neither handles sub-directories nor ignores hidden or system
files.

Here is my FSO solution.

Option Explicit

Private Declare Function SHGetPathFromIDList Lib "shell32.dll" _
Alias "SHGetPathFromIDListA" _
(ByVal pidl As Long, _
ByVal pszPath As String) As Long

Private Declare Function SHBrowseForFolder Lib "shell32.dll" _
Alias "SHBrowseForFolderA" _
(lpBrowseInfo As BROWSEINFO) As Long

Private Type BROWSEINFO
hOwner As Long
pidlRoot As Long
pszDisplayName As String
lpszTitle As String
ulFlags As Long
lpfn As Long
lParam As Long
iImage As Long
End Type

Dim FSO As Object
Dim cnt As Long
Dim level As Long
Dim arFiles

Sub Folders()
Dim i As Long

Set FSO = CreateObject("Scripting.FileSystemObject")

arFiles = Array()
cnt = 0
level = 1

ReDim arFiles(2, 0)
arFiles(0, 0) = GetFolder()
If arFiles(0, 0) <> "" Then
arFiles(1, 0) = level
SelectFiles arFiles(0, 0)

Worksheets.Add.Name = "Files"
With ActiveSheet
.Cells(1, 1).Value = "Path"
.Cells(1, 2).Value = "Filename"
.Cells(1, 3).Value = "Date Created"
.Rows(1).Font.Bold = True
.Columns("A:C").EntireColumn.AutoFit
cnt = 1
For i = LBound(arFiles, 2) To UBound(arFiles, 2)
.Cells(i + 1, 1).Value = arFiles(0, i)
.Cells(i + 1, 2).Value = arFiles(1, i)
.Cells(i + 1, 3).Value = arFiles(2, i)
Next
End With
End If

End Sub

'-----------------------------------------------------------------------
Sub SelectFiles(ByVal sPath)
'-----------------------------------------------------------------------
Dim fldr As Object
Dim Folder As Object
Dim file As Object
Dim Files As Object

Set Folder = FSO.GetFolder(sPath)

Set Files = Folder.Files
For Each file In Files
If (file.Attributes And 2 Or _
file.Attributes And 4) Then
'2 is hidden, 4 is system
Else
cnt = cnt + 1
ReDim Preserve arFiles(2, cnt)
arFiles(0, cnt) = Folder.path
arFiles(1, cnt) = file.Name
arFiles(2, cnt) = Format(file.DateCreated, "dd mmm yyyy")
End If
Next file

level = level + 1
For Each fldr In Folder.Subfolders
SelectFiles fldr.path
Next

End Sub


'-------------------------------------------------------------
Function GetFolder(Optional ByVal Name As String = "Select a folder.")
As String
'-------------------------------------------------------------
Dim bInfo As BROWSEINFO
Dim path As String
Dim oDialog As Long

bInfo.pidlRoot = 0& 'Root folder = Desktop

bInfo.lpszTitle = Name

bInfo.ulFlags = &H1 'Type of directory to Return
oDialog = SHBrowseForFolder(bInfo) 'display the dialog

'Parse the result
path = Space$(512)

GetFolder = ""
If SHGetPathFromIDList(ByVal oDialog, ByVal path) Then
GetFolder = Left(path, InStr(path, Chr$(0)) - 1)
End If

End Function

'----------------------------- end-script -----------------------------


--

HTH

Bob Phillips
... looking out across Poole Harbour to the Purbecks
(remove nothere from the email address if mailing direct)
 
J

Jim Cone

rahela,

Or you could use my Excel add-in "List Files".
Comes with one page Word.doc install/use instructions.
Very easy to use and available - free - upon direct request.
(remove xxx from my e-mail address)

Regards,
Jim Cone
San Francisco, CA
(e-mail address removed)
 
F

Frank Kabel

Hi Martyn
change Bob's code as follows (I also corrected the overwriting of the
heading row):

Option Explicit

Private Declare Function SHGetPathFromIDList Lib "shell32.dll" _
Alias "SHGetPathFromIDListA" _
(ByVal pidl As Long, _
ByVal pszPath As String) As Long

Private Declare Function SHBrowseForFolder Lib "shell32.dll" _
Alias "SHBrowseForFolderA" _
(lpBrowseInfo As BROWSEINFO) As Long

Private Type BROWSEINFO
hOwner As Long
pidlRoot As Long
pszDisplayName As String
lpszTitle As String
ulFlags As Long
lpfn As Long
lParam As Long
iImage As Long
End Type

Dim FSO As Object
Dim cnt As Long
Dim level As Long
Dim arFiles

Sub Folders()
Dim i As Long

Set FSO = CreateObject("Scripting.FileSystemObject")

arFiles = Array()
cnt = 0
level = 1

ReDim arFiles(3, 0)
arFiles(0, 0) = GetFolder()
If arFiles(0, 0) <> "" Then
arFiles(1, 0) = level
SelectFiles arFiles(0, 0)

Worksheets.Add.Name = "Files"
With ActiveSheet
.Cells(1, 1).Value = "Path"
.Cells(1, 2).Value = "Filename"
.Cells(1, 3).Value = "Date Created"
.Cells(1, 4).Value = "Filesize"
.Rows(1).Font.Bold = True
.Columns(4).NumberFormat = "#,##0 "" KB"""
.Columns("A:D").EntireColumn.AutoFit
cnt = 1
For i = LBound(arFiles, 2) To UBound(arFiles, 2)
.Cells(i + 2, 1).Value = arFiles(0, i)
.Cells(i + 2, 2).Value = arFiles(1, i)
.Cells(i + 2, 3).Value = arFiles(2, i)
.Cells(i + 2, 4).Value = arFiles(3, i) / 1024
Next
End With
End If

End Sub

'----------------------------------------------------------------------
-
Sub SelectFiles(ByVal sPath)
'----------------------------------------------------------------------
-
Dim fldr As Object
Dim Folder As Object
Dim file As Object
Dim Files As Object

Set Folder = FSO.GetFolder(sPath)

Set Files = Folder.Files
For Each file In Files
If (file.Attributes And 2 Or _
file.Attributes And 4) Then
'2 is hidden, 4 is system
Else
cnt = cnt + 1
ReDim Preserve arFiles(3, cnt)
arFiles(0, cnt) = Folder.path
arFiles(1, cnt) = file.Name
arFiles(2, cnt) = Format(file.DateCreated, "dd mmm yyyy")
arFiles(3, cnt) = file.Size
End If
Next file

level = level + 1
For Each fldr In Folder.Subfolders
SelectFiles fldr.path
Next

End Sub


'-------------------------------------------------------------
Function GetFolder(Optional ByVal Name As String = "Select a
folder.") As String
'-------------------------------------------------------------
Dim bInfo As BROWSEINFO
Dim path As String
Dim oDialog As Long

bInfo.pidlRoot = 0& 'Root folder = Desktop

bInfo.lpszTitle = Name

bInfo.ulFlags = &H1 'Type of directory to
Return
oDialog = SHBrowseForFolder(bInfo) 'display the dialog

'Parse the result
path = Space$(512)

GetFolder = ""
If SHGetPathFromIDList(ByVal oDialog, ByVal path) Then
GetFolder = Left(path, InStr(path, Chr$(0)) - 1)
End If

End Function
 
F

Frank Kabel

Hi
you may also make the following change to Bob's (excellent) procedure:
Move the line
..Columns("A:D").EntireColumn.AutoFit
directly after the For - Next loop to ensure the autofitting of columns
A-D

To Bob: Hope you didn't mind I changed your code <vbg>
 
B

Bob Phillips

Frank Kabel said:
Hi
you may also make the following change to Bob's (excellent) procedure:
Move the line
.Columns("A:D").EntireColumn.AutoFit
directly after the For - Next loop to ensure the autofitting of columns
A-D
Click to expand...

Thanks, didn't spot that, just added it at the end after testing to save the
OP having to do it manually (when will I ever learn?).

To Bob: Hope you didn't mind I changed your code <vbg>
Click to expand...

Absolutely not Frank, it is not only helpful, you might do something I would
not have thought of, so all benefit. It's a co-operative here, part of it's
richness, and I am not averse to adding my bit to other's postings. I was
unavailable for the past 2 hours anyway, had to make some flapjacks
 
F

Frank Kabel

Absolutely not Frank, it is not only helpful, you might do something
I would not have thought of, so all benefit. It's a co-operative
here, part of it's richness, and I am not averse to adding my bit to
other's postings. I was unavailable for the past 2 hours anyway, had
to make some flapjacks
Click to expand...

Sound delicious. So you semm to enjoy your weekend :)
Frank
 
R

rahela

Frank said:
*

Sound delicious. So you semm to enjoy your weekend :)
Frank *
Click to expand...

Hi Dear fellows,
Do I need to choose some library in the vbe, before I could use tha
programe? what I have forgot to mention is that I use
a local net. Would the programe above will be good for a net too?
From the discussion above, and the corrections, which
is the last best version (I am not an expert, and quite frankly
I got lost along the lines........) to use?
Thanks a zilio
 
B

Bob Phillips

Rahela,

You don't need a library as the code uses late binding (specifically to
avoid such problems).

It should work on a network as I included a Folder browser, and as long as
you have mapped drives to the network server(s), so you pick your folder to
list.

Use Frank's last amendment.

--

HTH

Bob Phillips
... looking out across Poole Harbour to the Purbecks
(remove nothere from the email address if mailing direct)
 

Ask a Question

Want to reply to this thread or ask your own question?

You'll need to choose a username for the site, which only take a couple of moments. After that, you can post your question and our members will help you out.

Ask a Question

Similar Threads

NEED CORRECTION IN MACRO 2
Using macro to do same task with different cells 2
Excel VBA - Problem with Closing Print Preview 0
Finding files using Dir 2
inconsistent dir() behavior 1
execution speed issue when closing files 5
Option-Group Variable (how to pass the value from FORM to MODULE) 1
XML API in VBA under Excel? 1

Top