using a function based on the value of a function

[Guest]

Can anyone provide instruction on how to make a secondary function (in a
separate column) look up the value (result) of the first function without
having to paste the values. Thanks in advance!

 

[zackb]

Hi Judy,

Not sure if I follow. But maybe you can use an IF function ...

=IF(A1=4,"A1 equals 4","")

This says that if the value (formula result) of A1 equals a numeric value of
4, then have this formula return the text "A1 equals 4"; and if it doesn't,
then return a null string ( "" ). Does this help?

 

[Bob Phillips]

Example

A1:17
B1:=A1*2
C1:=IF(B1>30,">30","<30")

is that what you mean?

--

HTH

RP
(remove nothere from the email address if mailing direct)

 

[Guest]

thanks to Bob and Zack -

now, I've got a long if statement, but it's not working perfectly yet. Do I
need to have ampersands or quotes anywhere that I missed? Do I have my less
than/greater than/equal signs mixed up?

=IF(G4<=0.249,"A",(IF(G4>=0.25<=0.399,"B",(IF(G4>=0.4<=0.499,"C",(IF(G4>=0.5<=0.599,"D",(IF(G4>=0.6<=0.849,"E",(IF(G4>=0.85<=1.749,"F",(IF(G4>=1.75<=3.149,"G",(IF(G4>=3.15<=99.999,"H","")))))))))))))))

I'm trying to have this cell compute a letter (A thru H) based on ranges.

Thanks!

 

[Bob Phillips]

Judy,

If comparing two values, you need AND, such as

G4>=0.25<=0.399 should be AND(G4>=0.25,G4<=0.399)

but in this case the previous test precludes re-testing the first part, so
all you need is

=IF(G4<=0.249,"A",(IF(G4<=0.399,"B",(IF(G4<=0.499,"C",(IF(G4<=0.599,"D",(IF(
G4<=0.849,"E",(IF(G4<=1.749,"F",(IF(G4<=3.149,"G",(IF(G4<=99.999,"H","")))))
))))))))))

--

HTH

RP
(remove nothere from the email address if mailing direct)

thanks to Bob and Zack -

now, I've got a long if statement, but it's not working perfectly yet. Do I
need to have ampersands or quotes anywhere that I missed? Do I have my less
than/greater than/equal signs mixed up?

=IF(G4<=0.249,"A",(IF(G4>=0.25<=0.399,"B",(IF(G4>=0.4<=0.499,"C",(IF(G4>=0.5

 

[zackb]

You could also accumulate that into only 1 or 2 IF functions ...

=IF(G4>0.25,IF(G4>=100,"Over",LOOKUP(G4,{0.25,"B";0.4,"C";0.5,"D";0.6,"E";0.85,"F";1.75,"G";3.15,"H"})),"A")

The only reason you'd need the IF's are to deal with high or low values.

HTH