SUMPRODUCT Help

  • Thread starter Sam via OfficeKB.com
  • Start date
S

Sam via OfficeKB.com

Hi All,

I'm using the Formula below to sum the count of the numeric value housed in
cell D4 for the month of July.

How can I amend the Formula below to use the MONTH function with a Cell
Reference housing a Custom Date Format: so where I've got = 7 for July, I
would like to use cell B6 which displays 01/07/2005 but is formatted as Jul-
2005 Custom Date mmm-yyyy.

Results is a Dynamic Range spanning 8 Columns and many Rows. The numeric
value is checked from the 3rd to the 7th Column (spans 5 columns). The date
is a single column (formatted 01/07/2005) - located in the 2nd Column of the
Dynamic Range.

The value housed in cell D4 is a numeric value.

=SUMPRODUCT((OFFSET(Results,0,2,,5)=$D$4)*((MONTH(OFFSET(Results,0,1,,1))=7))
)


Thanks
Sam
 
D

Domenic

Try...

=SUMPRODUCT((OFFSET(Results,0,2,,5)=$D$4)*(MONTH(OFFSET(Results,0,1,,1))=
MONTH($B$6)))

Note that if B6 contains a date whose month is January, all empty cells
in your date range will be evaluated as TRUE. You may want to try the
following instead...

=SUMPRODUCT((OFFSET(Results,0,2,,5)=$D$4)*(MONTH(OFFSET(Results,0,1,,1))=
MONTH($B$6))*(OFFSET(Results,0,1,,1)<>""))

Hope this helps!
 
S

Sam via OfficeKB.com

Hi Domenic,

I used your second option: Formula works great! Thank you very much.
=SUMPRODUCT((OFFSET(Results,0,2,,5)=$D$4)*(MONTH(OFFSET(Results,0,1,,1))=MONTH($B$6))*(OFFSET(Results,0,1,,1)<>""))

Cheers,
Sam
Try...

=SUMPRODUCT((OFFSET(Results,0,2,,5)=$D$4)*(MONTH(OFFSET(Results,0,1,,1))=
MONTH($B$6)))

Note that if B6 contains a date whose month is January, all empty cells
in your date range will be evaluated as TRUE. You may want to try the
following instead...

=SUMPRODUCT((OFFSET(Results,0,2,,5)=$D$4)*(MONTH(OFFSET(Results,0,1,,1))=
MONTH($B$6))*(OFFSET(Results,0,1,,1)<>""))

Hope this helps!
[quoted text clipped - 18 lines]
Thanks
Sam
 

Ask a Question

Want to reply to this thread or ask your own question?

You'll need to choose a username for the site, which only take a couple of moments. After that, you can post your question and our members will help you out.

Ask a Question

Top