sumif with >or< condition

[Will Fleenor]

I have 6 numbers in cells a1..a6. Some are positive and some are negative.
I would like to total up only the numbers that are > 20000 or <-20000.
This formula works for >
=SUMIF(A1:A6,">"&20000,A1:A6)
but this formula will not work:
=SUMIF(A1:A6,or(">"&20000,A1:A6,"<"&-20000),A1:A6 )
What is wrong with the last formula. It always evaluates to 0.

Thanks Will

 

[Pete_UK]

You can only have one condition with SUMIF. Try this:

=SUMIF(A1:A6,">"&20000,A1:A6)+SUMIF(A1:A6,"<"&-20000,A1:A6)

Hope this helps.

Pete

 

[Guest]

I got it to work with this:

=SUM(IF(ABS(A1:A6)>20000,A1:A6))

Activate with CTRL SHIFT ENTER

 

[Ragdyer]

=Sumif(A1:A6,">20000")+Sumif(A1:A6,"<-20000")

 

[Ragdyer]

OR this:

=SUMPRODUCT(((A1:A6>2)+(A1:A6<-2))*A1:A6)

 

[Guest]

=SUMIF(A1:A6,">20000",A1:A6)+SUMIF(A1:A6,"<-20000",A1:A6)

 

[Ragdyer]

Of course, add the 0's:

=SUMPRODUCT(((A1:A6>20000)+(A1:A6<-20000))*A1:A6)

 

[RagDyeR]

One more:<g>

=SUM(SUMIF(A1:A6,{">20000","<-20000"}))

--

HTH,

RD
=====================================================
Please keep all correspondence within the Group, so all may benefit!
=====================================================

Of course, add the 0's:

=SUMPRODUCT(((A1:A6>20000)+(A1:A6<-20000))*A1:A6)

 

[Bob Phillips]

Yet one more

=SUMPRODUCT(--(ABS(A1:A20)>2000),A1:A20)

--
HTH

Bob

(there's no email, no snail mail, but somewhere should be gmail in my addy)