sumif using the now() function

[Guest]

I am trying to sum numbers using the NOW() function as my criteria, however
no luck.

sumif($D$1:$BC$1. ">=NOW()", D2:BC2) Any help would be appreciated.

Thank you

 

[renegan]

Try this:

Assuming you try to sum D2 to BC2 on your example.

=if($D$1:$BC$1>=Now(),sum(D2:BC2),""

 

[Guest]

renegan: Thanks for your response, however I got #VALUE! in the cell. Any
suggestions

 

[Pete_UK]

Here's another variation to try:

=SUM(IF($D$1:$BC$1>=Now(),D2:BC2,0))

This is an array formula, so when you have typed it in (and if you
subsequently edit it) use CTRL-SHIFT-ENTER rather than just ENTER - if
you do this correctly then Excel will wrap curly braces { } around the
formula. You should not type these yourself.

You can copy the formula down if you wish.

Hope this helps.

Pete

 

[Peo Sjoblom]

Are you comparing dates and times or just times? If dates and times

=SUMIF(D1:BC1,">="&NOW(),D2:BC2)

with times only


=SUMIF(D1:BC1,">="&MOD(NOW(),1),D2:BC2)


--

Regards,

Peo Sjoblom

http://nwexcelsolutions.com

 

[renegan]

Ok:

$D$1:$BC$1>=Now() doesn't work. 2 things you can do:

1- You can use AND($D$1>=Now,$E$1>=Now,..........,$BC$1>=Now) which
won't be pretty
2- Create another row under the row you check the data, check each cell
condition one by one with an if statement and get 1 if true like:
D2=If($D$1>=Now,1,0)
Add all the cells with 1 and 0s. If total is less than the number of
columns between D and BC, then you don't add, if it does you do the
sum. Like:
if(Sum(D2:BC2)=52,sum(D2:BC2),"")

 

[Guest]

Pete, Peo. Thank you very much..... both formulas worked. U2 renegan 4 ur time

Regards
Gene Haines