Sum values between two ranges

[bren]

Hi,

I have a column with data between 1000 and 20000. I need to sum the
data between 2550 and 5661. How can I do this? What function does
this?

Thank you so much.

 

[Ron Coderre]

With Col_A containing your list of numbers

This formula returns the sum of values that are
between 2550 and 5661, inclusive:
B1: =SUMIF(A:A,"<=5661")-SUMIF(A:A,"<2550")

or...for more flexibility...
C1: (the lower limit...eg 2550)
D1: (the upper limit...eg 5661)
B1: =SUMIF(A:A,"<="&D1)-SUMIF(A:A,"<"&C1)

Does that help?

Regards,

Ron Coderre
Microsoft MVP (Excel)

 

[Don Guillett]

Unless I'm missing something, SUM
=sum(a2440:a5661)

 

[Pete_UK]

Try this:

=SUMIF(A:A,"<"&5661) - SUMIF(A:A,"<="&2550)

assuming your numbers are in column A. This will exclude the numbers
5661 and 2550, as you said you wanted to add those between this range.

Hope this helps.

Pete

 

[JoelS]

Hi,

I have a column with data between 1000 and 20000. I need to sum the
data between 2550 and 5661. How can I do this? What function does
this?

Thank you so much.

I think this is one possible solution:

Let's assume your data is in the range A1:10--

=SUM((a1:a10>=2550)*(A1:A10<=5661)*A1:A10)
and hit CNTRL-SHFT-ENTER

 

[Don Guillett]

I guess I WAS missing something.

 

[Bob Umlas]

=SUMPRODUCT(N(A1:A10000>=2550),N(A1:A10000<=5661),A1:A10000)
Bob Umlas
Excel MVP