Sum every 10th cell in a range of cells?

[Guest]

Is it possible to Sum every 10th cell in a range of cells (i.e.
a10+a20+a30....in a range of a1:a500) without entering every cell manually?
Thanks.

 

[Bernie Deitrick]

JKJ95

=SUMPRODUCT((MOD(ROW(A1:A500),10)=0)*A1:A500)

HTH,
Bernie
MS Excel MVP

 

[Bob Umlas]

=SUMPRODUCT((A1:A500)*(MOD(ROW(1:500),10)=0))
Bob Umlas
Excel MVP

 

[Domenic]

Try...

=SUMPRODUCT(--(MOD(ROW(A1:A500)-CELL("row",A1)+1,10)=0),A1:A500)

In instances where you want to sum every 10th cell starting from A1,
change the +1 part of the formula to +0...

=SUMPRODUCT(--(MOD(ROW(A1:A500)-CELL("row",A1)+0,10)=0),A1:A500)

Hope this helps!

 

[Tom Ogilvy]

=SUM(IF(MOD(ROW(A1:A500),10)=0,A1:A500))

Entered with Ctrl+Shift+Enter rather than just enter since this is an array
formula.

 

[Guest]

=SUMPRODUCT(--(MOD(ROW(A1:A500),10)=0),A1:A500)

 

[Guest]

Try something like this:
=SUMPRODUCT(--(MOD(ROW($A$10:$A$30)-ROW($B$10),10)=0)*$A$10:$A$30)

 

[Jerry W. Lewis]

=SUMPRODUCT(((MOD(A1:A500,10)=0)*A1:A500))

Jerry

 

[Guest]

You probably meant

=SUMPRODUCT(((MOD(ROW(A1:A500),10)=0)*A1:A500))

Alok Joshi

 

[Jerry W. Lewis]

True

You probably meant

=SUMPRODUCT(((MOD(ROW(A1:A500),10)=0)*A1:A500))

Alok Joshi

: