Stronger highlighting of rows for xl97 ?

[Sirritys]

Hi,

In latter versions of XL the highlighting of selected row and columns
is nice and clear.

However in XL 97 exels just highlights (or drops shadow) the column
letter and row number a little bit.

It' really annoying when you have hard time to determine which
row/column you are in.

Any fix for this ?

 

[Pete_UK]

Microsoft changed the highlighting in Excel 2000. I don't think you can
change it in Excel 97 to be the same.

Pete

 

[Bob Phillips]

Try this


'----------------------------------------------------------------
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
'----------------------------------------------------------------
Cells.FormatConditions.Delete
With Target
With .EntireRow
.FormatConditions.Add Type:=xlExpression, Formula1:="TRUE"
With .FormatConditions(1)
With .Borders(xlTop)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = 5
End With
With .Borders(xlBottom)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = 5
End With
.Interior.ColorIndex = 20
End With
End With
With .EntireColumn
.FormatConditions.Delete
.FormatConditions.Add Type:=xlExpression, Formula1:="TRUE"
With .FormatConditions(1)
With .Borders(xlLeft)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = 5
End With
With .Borders(xlRight)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = 5
End With
.Interior.ColorIndex = 20
End With
End With

.FormatConditions.Delete
.FormatConditions.Add Type:=xlExpression, Formula1:="TRUE"
.FormatConditions(1).Interior.ColorIndex = 36
End With

End Sub


'This is worksheet event code, which means that it needs to be
'placed in the appropriate worksheet code module, not a standard
'code module. To do this, right-click on the sheet tab, select
'the View Code option from the menu, and paste the code in.

--
HTH

Bob Phillips

(replace somewhere in email address with gmail if mailing direct)

 

[Dave Peterson]

you may want to try Chip Pearson's Rowliner:
http://www.cpearson.com/excel/RowLiner.htm

 

[Sirritys]

Thanks man,

This is by far coolest (and usefull) vba script I have met so far =)

regards,
Sirritys