stop copy highlight without clearing clipboard

[RB Smissaert]

Is it possible to put a range on the clipboard, then stop the copied range
highlight (the walking ants) without
clearing the clipboard?

RBS

 

[Nick Hodge]

RBS

Not as far as I know, the walking ants show Excel is in CutCopyMode, setting
this to false clears the clipboard...why not save the data to a hidden sheet
or similar?

--
HTH
Nick Hodge
Microsoft MVP - Excel
Southampton, England
www.nickhodge.co.uk
(e-mail address removed)

 

[Guest]

To the best of my knowledge, no.

You might be able to do something with the screenupdating command.

 

[Alf Bryn]

Since the clipboard can store a number of items (Excel 2003) you could
perhaps copy a cell somewhere after you copied the range to the clipboard.

This will stop "the walking ants" on your range but the cell you selected
will still have them.

 

[RB Smissaert]

Found a way that suits my purpose as I don't need the formatting:


Sub RangeTextToClipBoard(rng As Range)

'Needs a reference to the Microsoft Forms 2.0 Object Library
'but doesn't need an actual UserForm in the Project
'-----------------------------------------------------------

Dim i As Long
Dim c As Long
Dim arr
Dim strRange As String
Dim oDataObject As DataObject

Set oDataObject = New DataObject

If rng.Cells.Count = 1 Then
strRange = rng
Else
arr = rng
For i = 1 To UBound(arr)
For c = 1 To UBound(arr, 2)
If c < UBound(arr, 2) Then
strRange = strRange & arr(i, c) & vbTab
Else
If i < UBound(arr) Then
strRange = strRange & arr(i, c) & vbCrLf
Else
strRange = strRange & arr(i, c)
End If
End If
Next
Next
End If

With oDataObject
.SetText strRange
.PutInClipboard
End With

End Sub


Sub Test()

RangeTextToClipBoard Range(Cells(1), Cells(2, 4))

End Sub


RBS