SP2 Installation

G

Guest

After one successful installation of SP2 I have had a problem on the second
machine. Installation went through the backup registry and restore point
process and then errored out with the following message:
"Unable to read from or write to the data base"

Following is svcpack.log entries from restore point forward:

1016.822: System Restore Point set.
1018.094: PFE2: Per File Exceptions will not be used.
1024.463: SceConfigreSystem failed, return 0x14
1024.463: DoInstallation:SecurityConfigSystemCommit Failed: 0x800710d9
1056.730: UnRegisterSpuninstForRecovery, failed to delete SpRecoverCmdLine
value, error 0x2
1056.730: DoInstallation: Failed to unregistering spuninst.exe for recovery.
1056.780: Unable to read from or write to the database.
1080.143: Message displayed to the user: Unable to read from or write to the
database.
1080.143: User Input: OK
1222.949: DeRegistering the Uninstall Program -> Windows XP Service Pack, 0
1222.949: Service Pack 2 installation did not complete.
1224.821: Message displayed to the user: Service Pack 2 installation did not
complete.
1224.821: User Input: OK
1224.821: Update.exe extended error code = 0x800710d9

Need help!!!!
 
T

Torgeir Bakken \(MVP\)

BIGAL said:
After one successful installation of SP2 I have had a problem on the second
machine. Installation went through the backup registry and restore point
process and then errored out with the following message:
"Unable to read from or write to the data base"
Hi

Try this:

Place the text below in a .bat (batch) file (e.g. paste it into a new
notepad document and save it with e.g. the name fixdb.bat)

Then run the batch file by double clicking on it.

You should run the batch file just after a reboot of the computer (as
the first thing).

The batch file will tell you when it is finished.

Please post any result back here, good or bad :)

Start batch file:
--------------------8<----------------------

@echo off
:: Batch file that tries to remedy error # 800710D9
:: "Unable to read from or write to the database".
:: Author: Torgeir Bakken
:: Date: 2004-08-30

:: Stop the Cryptographic service
%SystemRoot%\System32\net.exe stop CryptSvc

:: Rename all log files in the %SystemRoot%\Security folder
FOR %%a in (%SystemRoot%\Security\*.log) DO move /y %%a %%a.old

:: Rename the %SystemRoot%\System32\CatRoot2 folder
move /y %SystemRoot%\System32\CatRoot2 %SystemRoot%\System32\CatRoot2old

IF not exist %SystemRoot%\System32\CatRoot2 GOTO CONT01

:: In case the folder rename failed because of locked files
:: rename all log files in the %SystemRoot%\System32\CatRoot2 folder
FOR %%a in (%SystemRoot%\System32\CatRoot2\*.log) DO move /y %%a %%a.old
SET catroot2locked=True

:CONT01
cls
echo.
echo Please wait, this might take some time...

:: Unregister DLL files that are associated with Cryptographic Services
CD /D %SystemRoot%\System32
start /wait regsvr32.exe /s /u softpub.dll
start /wait regsvr32.exe /s /u wintrust.dll
start /wait regsvr32.exe /s /u initpki.dll
start /wait regsvr32.exe /s /u dssenh.dll
start /wait regsvr32.exe /s /u rsaenh.dll
start /wait regsvr32.exe /s /u gpkcsp.dll
start /wait regsvr32.exe /s /u sccbase.dll
start /wait regsvr32.exe /s /u slbcsp.dll
start /wait regsvr32.exe /s /u cryptdlg.dll

:: Reregister DLL files that are associated with Cryptographic Services
start /wait regsvr32.exe /s softpub.dll
start /wait regsvr32.exe /s wintrust.dll
start /wait regsvr32.exe /s initpki.dll
start /wait regsvr32.exe /s dssenh.dll
start /wait regsvr32.exe /s rsaenh.dll
start /wait regsvr32.exe /s gpkcsp.dll
start /wait regsvr32.exe /s sccbase.dll
start /wait regsvr32.exe /s slbcsp.dll
start /wait regsvr32.exe /s cryptdlg.dll

:: Configure and start the Cryptographic service
%SystemRoot%\system32\sc.exe config CryptSvc start= auto
:: Start the Cryptographic Service
%SystemRoot%\system32\net.exe start CryptSvc
cls

echo.
If "%catroot2locked%"=="True" GOTO CONT02
echo Finished, please reboot the computer and then try to install SP2 again...

GOTO END
:CONT02
echo Please run the batch file again with a newly restarted computer...
echo (but if it is newly restarted, just do a reboot and then try
echo to install SP2 again)...
GOTO END

:END
echo.
pause

--------------------8<----------------------
 
G

Guest

Torgeir, your suggestion worked. Thanks a lot.

Torgeir Bakken (MVP) said:
Hi

Try this:

Place the text below in a .bat (batch) file (e.g. paste it into a new
notepad document and save it with e.g. the name fixdb.bat)

Then run the batch file by double clicking on it.

You should run the batch file just after a reboot of the computer (as
the first thing).

The batch file will tell you when it is finished.

Please post any result back here, good or bad :)

Start batch file:
--------------------8<----------------------

@echo off
:: Batch file that tries to remedy error # 800710D9
:: "Unable to read from or write to the database".
:: Author: Torgeir Bakken
:: Date: 2004-08-30

:: Stop the Cryptographic service
%SystemRoot%\System32\net.exe stop CryptSvc

:: Rename all log files in the %SystemRoot%\Security folder
FOR %%a in (%SystemRoot%\Security\*.log) DO move /y %%a %%a.old

:: Rename the %SystemRoot%\System32\CatRoot2 folder
move /y %SystemRoot%\System32\CatRoot2 %SystemRoot%\System32\CatRoot2old

IF not exist %SystemRoot%\System32\CatRoot2 GOTO CONT01

:: In case the folder rename failed because of locked files
:: rename all log files in the %SystemRoot%\System32\CatRoot2 folder
FOR %%a in (%SystemRoot%\System32\CatRoot2\*.log) DO move /y %%a %%a.old
SET catroot2locked=True

:CONT01
cls
echo.
echo Please wait, this might take some time...

:: Unregister DLL files that are associated with Cryptographic Services
CD /D %SystemRoot%\System32
start /wait regsvr32.exe /s /u softpub.dll
start /wait regsvr32.exe /s /u wintrust.dll
start /wait regsvr32.exe /s /u initpki.dll
start /wait regsvr32.exe /s /u dssenh.dll
start /wait regsvr32.exe /s /u rsaenh.dll
start /wait regsvr32.exe /s /u gpkcsp.dll
start /wait regsvr32.exe /s /u sccbase.dll
start /wait regsvr32.exe /s /u slbcsp.dll
start /wait regsvr32.exe /s /u cryptdlg.dll

:: Reregister DLL files that are associated with Cryptographic Services
start /wait regsvr32.exe /s softpub.dll
start /wait regsvr32.exe /s wintrust.dll
start /wait regsvr32.exe /s initpki.dll
start /wait regsvr32.exe /s dssenh.dll
start /wait regsvr32.exe /s rsaenh.dll
start /wait regsvr32.exe /s gpkcsp.dll
start /wait regsvr32.exe /s sccbase.dll
start /wait regsvr32.exe /s slbcsp.dll
start /wait regsvr32.exe /s cryptdlg.dll

:: Configure and start the Cryptographic service
%SystemRoot%\system32\sc.exe config CryptSvc start= auto
:: Start the Cryptographic Service
%SystemRoot%\system32\net.exe start CryptSvc
cls

echo.
If "%catroot2locked%"=="True" GOTO CONT02
echo Finished, please reboot the computer and then try to install SP2 again...

GOTO END
:CONT02
echo Please run the batch file again with a newly restarted computer...
echo (but if it is newly restarted, just do a reboot and then try
echo to install SP2 again)...
GOTO END

:END
echo.
pause

--------------------8<----------------------


--
torgeir, Microsoft MVP Scripting and WMI, Porsgrunn Norway
Administration scripting examples and an ONLINE version of
the 1328 page Scripting Guide:
http://www.microsoft.com/technet/scriptcenter/default.mspx
 
S

Sabrina

Torgeir, you are genious! Many thanks from me too :) .

I only think there should be 'move /h' (instead of 'move /y') in the batch.
 
T

Torgeir Bakken \(MVP\)

Sabrina said:
Torgeir, you are genious! Many thanks from me too :) .

Your welcome :)
I only think there should be 'move /h' (instead of 'move /y')
in the batch.

No, I use /y in case there exists files/folders there from before.

A quote from "move.exe /?":

/Y Suppresses prompting to confirm you want to
overwrite an existing destination file.


I can't see that /h is supported by move.exe at all?
 
S

Sabrina

Torgeir Bakken \(MVP\) said:
No, I use /y in case there exists files/folders there from before.

A quote from "move.exe /?":

/Y Suppresses prompting to confirm you want to
overwrite an existing destination file.


I can't see that /h is supported by move.exe at all?

Oops... Sorry, you are right. I ran it under 4NT command shell, which
needs "move /H" for hidden and system files.
 
F

Fgow

Torgeir said:
Hi

Try this:

Place the text below in a .bat (batch) file (e.g. paste it into
new
notepad document and save it with e.g. the name fixdb.bat)

Then run the batch file by double clicking on it.

You should run the batch file just after a reboot of the compute
(as
the first thing).

The batch file will tell you when it is finished.

Please post any result back here, good or bad :)

Start batch file:
--------------------8<----------------------

@echo off
:: Batch file that tries to remedy error # 800710D9
:: "Unable to read from or write to the database".
:: Author: Torgeir Bakken
:: Date: 2004-08-30

:: Stop the Cryptographic service
%SystemRoot%\System32\net.exe stop CryptSvc

:: Rename all log files in the %SystemRoot%\Security folder
FOR %%a in (%SystemRoot%\Security\*.log) DO move /y %%a %%a.old

:: Rename the %SystemRoot%\System32\CatRoot2 folder
move /y %SystemRoot%\System32\CatRoot
%SystemRoot%\System32\CatRoot2old

IF not exist %SystemRoot%\System32\CatRoot2 GOTO CONT01

:: In case the folder rename failed because of locked files
:: rename all log files in the %SystemRoot%\System32\CatRoot2 folder
FOR %%a in (%SystemRoot%\System32\CatRoot2\*.log) DO move /y %%
%%a.old
SET catroot2locked=True

:CONT01
cls
echo.
echo Please wait, this might take some time...

:: Unregister DLL files that are associated with Cryptographi
Services
CD /D %SystemRoot%\System32
start /wait regsvr32.exe /s /u softpub.dll
start /wait regsvr32.exe /s /u wintrust.dll
start /wait regsvr32.exe /s /u initpki.dll
start /wait regsvr32.exe /s /u dssenh.dll
start /wait regsvr32.exe /s /u rsaenh.dll
start /wait regsvr32.exe /s /u gpkcsp.dll
start /wait regsvr32.exe /s /u sccbase.dll
start /wait regsvr32.exe /s /u slbcsp.dll
start /wait regsvr32.exe /s /u cryptdlg.dll

:: Reregister DLL files that are associated with Cryptographi
Services
start /wait regsvr32.exe /s softpub.dll
start /wait regsvr32.exe /s wintrust.dll
start /wait regsvr32.exe /s initpki.dll
start /wait regsvr32.exe /s dssenh.dll
start /wait regsvr32.exe /s rsaenh.dll
start /wait regsvr32.exe /s gpkcsp.dll
start /wait regsvr32.exe /s sccbase.dll
start /wait regsvr32.exe /s slbcsp.dll
start /wait regsvr32.exe /s cryptdlg.dll

:: Configure and start the Cryptographic service
%SystemRoot%\system32\sc.exe config CryptSvc start= auto
:: Start the Cryptographic Service
%SystemRoot%\system32\net.exe start CryptSvc
cls

echo.
If "%catroot2locked%"=="True" GOTO CONT02
echo Finished, please reboot the computer and then try to install SP
again...

GOTO END
:CONT02
echo Please run the batch file again with a newly restarte
computer...
echo (but if it is newly restarted, just do a reboot and then try
echo to install SP2 again)...
GOTO END

:END
echo.
pause

--------------------8<----------------------


--
torgeir, Microsoft MVP Scripting and WMI, Porsgrunn Norway
Administration scripting examples and an ONLINE version of
the 1328 page Scripting Guide:
http://www.microsoft.com/technet/scriptcenter/default.mspx *

YOU ARE THE MAN.
I was about ready to re-instal XP then desided to do a search, and I a
glad I did.

Thanks a To


-
Fgo
 
G

Guest

:
-snip-
Try this:

Place the text below in a .bat (batch) file (e.g. paste it into a new
notepad document and save it with e.g. the name fixdb.bat)

Then run the batch file by double clicking on it.

Thanks,

After hours and hours trying to find why my Wife's Dell couldn't install
SP2, I found your post and it worked perfectly. All my other machines had no
problem.

Doug
 
A

aligaus

This is what i keep getting - any ideas???
Please !!??


9.906: 2006/06/29 20:04:53.277 (local)
9.922: c:\61af9338e20457d03088\i386\update\update.exe (version
5.5.1005.0)
9.953: Service Pack started with following command line:
10.250: Return Value From OnACPower = 1
10.250: OnACPower returned value( 0x1 ) which is Equal To 0x1
10.250: Condition succeeded for section OnACPower.Section in Line 1 of
PreRequisite
10.250:
SOFTWARE\Microsoft\Windows\CurrentVersion\Setup\WindowsFeatures is not
Present
10.250: First Condition in A6Block.Section Succeeded
10.250: Condition succeeded for section A6Block.Section in Line 2 of
PreRequisite
21.828: PrepareToTrustInfFile: MySetupCopyOEMInf failed: 0x5
21.828: IsInfFileTrusted: PrepareToTrustInfFile Failed: 0x5
21.906: UnRegisterSpuninstForRecovery, failed to delete
SpRecoverCmdLine value, error 0x2
21.906: DoInstallation: Failed to unregistering spuninst.exe for
recovery.
21.937: Access is denied.
24.062: Message displayed to the user: Access is denied.
24.062: User Input: OK
24.062: Service Pack 2 installation did not complete.
25.218: Message displayed to the user: Service Pack 2 installation did
not complete.
25.218: User Input: OK
25.218: Update.exe extended error code = 0x5
25.218: Update.exe return code was masked to 0x643 for MSI custom
action compliance.
 
J

JS Bauman

11/04/2009
Greetings:

I have the following system: IBM, Model: ThinkPad T22 2647 M4U,
OS: Win XP Pro. I am trying to upgrade the SP to SP2. By continued efforts
I am at the point where I am also getting the following from restore point
forward:

3212.319: Policy restored to 1
3213.521: UpdateMonitoredList Succeeded
3828.755: System Restore Point set.
3829.296: PFE2: Per File Exceptions will not be used.
3850.727: SceConfigreSystem failed, return 0x14
3850.727: DoInstallation:SecurityConfigSystemCommit Failed: 0x800710d9
3932.685: UnRegisterSpuninstForRecovery, failed to delete SpRecoverCmdLine
value, error 0x2
3932.685: DoInstallation: Failed to unregistering spuninst.exe for recovery.
3932.685: Unable to read from or write to the database.
3948.748: Message displayed to the user: Unable to read from or write to the
database.
3948.748: User Input: OK
3954.797: DeRegistering the Uninstall Program -> Windows XP Service Pack, 0
3954.797: Service Pack 2 installation did not complete.
3957.601: Message displayed to the user: Service Pack 2 installation did not
complete.
3957.601: User Input: OK
3957.601: Update.exe extended error code = 0x800710d9
3957.601: Update.exe return code was masked to 0x643 for MSI custom action
compliance.

However, I have already been running Torgeir Bakken’s batch file (with the
added inclusion of Mssip32.dll as the 10th file to be Unregistered /
re-registered). “3850.727: SceConfigreSystem failed, return 0x14†seems to
be the current point of contention. Does anyone have any suggestions as to
how to proceed from here?

Respectfully,

JS Bauman
 

Ask a Question

Want to reply to this thread or ask your own question?

You'll need to choose a username for the site, which only take a couple of moments. After that, you can post your question and our members will help you out.

Ask a Question

Top