Select a Row where the cursor is active

[daved37]

Hello,

How can I in VBA select a entire rows("number:number") where the cursor
is active...so when the cursor moves through my for next statement it
keeps on selecting the proper rows that I need it too and skipping the
others?

Here's my code so far:

Dim rng As Range

For Each rng In Range("B1:B150")
If rng = "" Then
rng.Activate
Rows("rng").Select ' Here is what doesn't work
Selection.Locked = False
Selection.FormulaHidden = False
Else
rng.Activate
Rows("rng").Select ' Here is what doesn't work
Selection.Locked = True
Selection.FormulaHidden = True

End If

Next

Thanks in advance!

Dave

 

[Guest]

You really don't need the selects. Also rng is a range object. Think of it as
something that point at the cell. It can return the address of the cell or
the value or the anything about the cell (or range of cells)...

Give this a try...

Dim rng As Range

For Each rng In Range("B1:B150")
with rng
If .value = "" Then
.Locked = False
.FormulaHidden = False
Else
.Locked = True
.FormulaHidden = True
End If
End With
Next rng

 

[Norman Jones]

Hi Daved,

Try:

'=============>>
Public Sub Tester()
Dim rng As Range

For Each rng In Range("B1:B150")
With rng
.EntireRow.Locked = .Value <> ""
EntireRow.FormulaHidden = .Value <> ""
End With
Next
End Sub
'<<=============

 

[Guest]

Sorry I missed the entire row in my answer... That being said go with Norman
code with one small change (he missed a dot)

Public Sub Tester()
Dim rng As Range

For Each rng In Range("B1:B150")
With rng
.EntireRow.Locked = .Value <> ""
.EntireRow.FormulaHidden = .Value <> "" 'Missed the dot
End With
Next
End Sub

 

[Norman Jones]

Hi Jim,

Sorry I missed the entire row in my answer... That being said go with
Norman code with one small change (he missed a dot)

Thanks for the catch!