Right and Left Formula

[Guest]

Hello all,

I am trying to convert the text in cell A2 which is LAST NAME, FIRST NAME to
convert to FIRST NAME LAST NAME - No comma. I got pretty far with the
formula below.

This is what it looks like: Tackett, Raymond
This is what I want it to look like: Raymond Tackett
This is what the formula below makes it look like: RaymondTackett,

=(RIGHT(A2,LEN(A2)-FIND(" ",A2))) & (LEFT(A2,FIND(" ",A2,1)))

Thanks,

Raymond

 

[Domenic]

Try...

=RIGHT(A2,LEN(A2)-(FIND(",",A2)+1))&" "&LEFT(A2,FIND(",",A2)-1)

Hope this helps!

 

[swatsp0p]

You were close... try this:

=(RIGHT(G4,LEN(G4)-FIND(" ",G4))) &" "& (LEFT(G4,FIND(",",G4,1)-1))

Good Luck

 

[Guest]

This did make them in the correct format but it is skipping every other cell.
Awesome job though! It is changing A2, A4, A6, etc...

 

[Guest]

NEVERMIND. For some reason when I used your formula, it merged and wrap text

 

[Harlan Grove]

Domenic wrote...

Try...

=RIGHT(A2,LEN(A2)-(FIND(",",A2)+1))&" "&LEFT(A2,FIND(",",A2)-1)

You could dispense with the unnecessary LEN call by using MID

=MID(A2,FIND(",",A2)+2,1024)&" "&LEFT(A2,FIND(",",A2)-1)

or REPLACE

=REPLACE(A2,1,FIND(",",A2)+1,"")&" "&LEFT(A2,FIND(",",A2)-1)

 

[Domenic]

Thanks Harlan! Much appreciated!

Domenic wrote...

You could dispense with the unnecessary LEN call by using MID

=MID(A2,FIND(",",A2)+2,1024)&" "&LEFT(A2,FIND(",",A2)-1)

or REPLACE

=REPLACE(A2,1,FIND(",",A2)+1,"")&" "&LEFT(A2,FIND(",",A2)-1)