Report filter

[eddy via AccessMonster.com]

Hi,

I have a form called "OM_ASP_Scan" . User will search by "Tag No", numbers
that created by autonumber and input some information to update. I also have
created two combo box to specify print range between "Tag No" and a command
button to preview a report. In the On Click event I've entered the following
code:

Private Sub Command48_Click()

On Error GoTo Err_Command62_Click

Dim stDocName As String


stDocName = "ASP_Detail" 'report name

DoCmd.OpenReport stDocName, acViewPreview, , "[Tag No] between " & Me!
[Combo44] & " and " & Me![Combo46]

Exit_Command62_Click:
Exit Sub

Err_Command62_Click:
MsgBox Err.Description
Resume Exit_Command62_Click
End Sub

It's working prefectly except when I tried to add more combo box to filter
by user input date that called "Date Send" field. I want the report shows
the chosen date only. It was quite confusing to customize the code, due to
that I really appreciate if anybody could give me some hand.


Thank you.


Regards

eddy

 

[Duane Hookom]

I would rename the tagno combo boxes and use code like:
Private Sub Command48_Click()

On Error GoTo Err_Command62_Click

Dim stDocName As String
Dim strWhere as String

stDocName = "ASP_Detail" 'report name
strWhere = "1=1 "
If Not IsNull(Me.cboFrom) Then
strWhere = strWhere & " And [Tag No] >=" & Me.cboFrom
End If
If Not IsNull(Me.cboTo) Then
strWhere = strWhere & " And [Tag No] <=" & Me.cboTo
End If
If Not IsNull(Me.cboDate) Then
strWhere = strWhere & " And [Date Send] =#" & Me.cboDate & "#"
End If
DoCmd.OpenReport stDocName, acViewPreview, , strWhere

Exit_Command62_Click:
Exit Sub

Err_Command62_Click:
MsgBox Err.Description
Resume Exit_Command62_Click
End Sub

 

[eddy via AccessMonster.com]

Thanks for your fast reply and it works perfectly!!

Thanks again, god bless you

Regards

Eddy

I would rename the tagno combo boxes and use code like:
Private Sub Command48_Click()

On Error GoTo Err_Command62_Click

Dim stDocName As String
Dim strWhere as String

stDocName = "ASP_Detail" 'report name
strWhere = "1=1 "
If Not IsNull(Me.cboFrom) Then
strWhere = strWhere & " And [Tag No] >=" & Me.cboFrom
End If
If Not IsNull(Me.cboTo) Then
strWhere = strWhere & " And [Tag No] <=" & Me.cboTo
End If
If Not IsNull(Me.cboDate) Then
strWhere = strWhere & " And [Date Send] =#" & Me.cboDate & "#"
End If
DoCmd.OpenReport stDocName, acViewPreview, , strWhere

Exit_Command62_Click:
Exit Sub

Err_Command62_Click:
MsgBox Err.Description
Resume Exit_Command62_Click
End Sub

Hi,

[quoted text clipped - 38 lines]

eddy