Print drop-down lists in Word 2003 form

[Guest]

I want to print the choices in drop-down lists I created in a form. I can't
seem to find any reference to these lists in Help and I'm not able to
highlight the form box and copy/paste the choices. How?

 

[Jay Freedman]

The only way to do this is to program a macro. The following macro can be
pasted into Normal.dot or another template
(http://www.gmayor.com/installing_macro.htm). Then open a document
containing your form, and run the macro to create a separate document
containing the list of dropdown contents.

Sub ListDropdownChoices()
Dim fld As FormField
Dim lEntry As ListEntry
Dim srcDoc As Document, destDoc As Document
Dim destRg As Range

Set srcDoc = ActiveDocument
Set destDoc = Documents.Add

For Each fld In srcDoc.FormFields
If fld.Type = wdFieldFormDropDown Then
Set destRg = destDoc.Range

With destRg
.Collapse wdCollapseEnd
.Text = fld.Name & vbCr
.MoveEnd wdCharacter, -1
.Bold = True
End With

For Each lEntry In fld.DropDown.ListEntries
Set destRg = destDoc.Range
destRg.Collapse wdCollapseEnd
destRg.Text = lEntry.Name & vbCr
Next
End If
Next
End Sub

--
Regards,
Jay Freedman
Microsoft Word MVP
Email cannot be acknowledged; please post all follow-ups to the newsgroup so
all may benefit.

 

[Guest]

Thank you. Just thought and wish it would be easier than this! Seems like
something people would want to be able to do without writing a macro. Again,
thanks.