positioning charts

[Guest]

I am trying to create a number of charts using VBA, but positioning the
charts is giving me trouble. Thanks in advance for any help.

My code:

Set myChart = Charts.Add
ActiveChart.ChartType = xlXYScatterLines
ActiveChart.SetSourceData Source:=Sheets("Graph").Range(GraphRange),
PlotBy:=xlColumns
ActiveChart.Location Where:=xlLocationAsObject, Name:="Graph"
With myChart.Parent
.Top = Range("C2").Top
.Left = Range("C2").Left
End With

Error:
Run-time error '424'

Object required

 

[witek]

With ActiveChart.Parent
.Top = Range("C2").Top
.Left = Range("C2").Left
End With


mychart doesn't represent chart after changing location and only
Microsoft knows why.

 

[Norman Jones]

--

 

[Norman Jones]

Hi Mike,

Try something like:

'=============>>
Public Sub Tester()
Dim SH As Worksheet
Dim rng As Range
Dim myChart As ChartObject

Set SH = Sheets("Graph")
Set rng = SH.Range("GraphRange")

Set myChart = SH.ChartObjects.Add(Left:=SH.Range("C2").Left, _
Top:=SH.Range("C2").Top, _
Width:=300, _
Height:=200) '<<=== CHANGE


With myChart.Chart
.ChartType = xlXYScatterLines
.SetSourceData Source:=rng, PlotBy _
:=xlColumns
End With
End Sub
'<<=============