Open Excel with Just Menu Bar in Full Screen

[Guest]

I have a spreadsheet which will be completed by various users. I want the
spreadsheet to open up to a specific sheet (already got that) and only show
the Menu Bar. I want the user to be able to open another spreadsheet, not
this one and have their toolbars as they always do.
Is this possible?
Appreciate the advice!

 

[Bob Phillips]

Option Explicit

Private mFormulaBar

Private Sub Workbook_Activate()
ManageCBs False
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
ManageCBs True
End Sub

Private Sub Workbook_Deactivate()
ManageCBs True
End Sub

Private Sub Workbook_Open()
ManageCBs False
End Sub

Private Sub ManageCBs(Show As Boolean)
Dim oCB As CommandBar
For Each oCB In Application.CommandBars
oCB.Enabled = Show
Next oCB

If Show Then
Application.DisplayFormulaBar = mFormulaBar
Else
mFormulaBar = Application.DisplayFormulaBar
Application.DisplayFormulaBar = False
Application.CommandBars("Worksheet Menu Bar").Enabled = True
End If
End Sub


'This is workbook event code.
'To input this code, right click on the Excel icon on the worksheet
'(or next to the File menu if you maximise your workbooks),
'select View Code from the menu, and paste the code




--
HTH

Bob

(there's no email, no snail mail, but somewhere should be gmail in my addy)