Need help calculating overtime to date

[BVHis]

So here's the deal... I need to calculate the total number of overtime
hours to date. I've searched the threads but have come up short with
what I need to accomplish.

My spreadsheet has a TOTAL OVERTIME cell (A5). Cells B5 through BA5
represent the 52 weeks in a year. Each time a value is entered in any
of those cells, I would like the TOTAL OVERTIME value to update
(overtime is anything over 40 hours). So if 41 is entered in B5, the
total overtime to date would be 1. If 44 is entered in C5, the total
overtime to date would be 5 hours (1 hour from the previous week and 4
hours from this week).

This is the formula I found, but this only does one 40 hour period. I
need something a little more complex.

=IF(A5>=40,SUM(A5-40),"0")

Thanks in advance!

Matt W

 

[Daniel CHEN]

Try to use the following array function in cell A5
(assume that the standard full time is 40 hours)

=SUM(IF((($B$5:$BA$5)>40),$B$5:$BA$5-40))

Best regards,
---
Yongjun CHEN
Project Oriented Spreadsheet Development and Consulting
(e-mail address removed) - http://www.geocities.com/udqservices/UDQConsulting.htm



=================================

 

[SteveG]

=SUMPRODUCT(--(B5:BA5>40),--(B5:BA5))-SUMPRODUCT(--(B5:BA5>40))*40

or

=SUMPRODUCT(--(B5:BA5>40),--(B5:BA5))-COUNTIF(B5:BA5,">40")*40

HTH

Steve

 

[Roger Govier]

Hi

One way
=SUM(B5:BA5)-COUNTIF(B5:BA5,">0")*40

Basically, add all the hours in the range then deduct 40 times the
number of weeks that have data within them (>0).

 

[JE McGimpsey]

One way:

=SUMPRODUCT(--(B5:BA5>40),(B5:BA5-40))

 

[John Michl]

This seems to work. It is an array formula so you must use
Ctrl-Shift-Enter to commit it.

{=SUM(IF(B5:BA5>40,B5:BA5-40),0)}

(Note the { } symbols are not entered but are automatically inserted
when you commit with Ctrl-Shift-Enter.)

- John
www.JohnMichl.com

 

[John Michl]

This assumes that the minimum number of hours worked is 40. If someone
worked 39 hours in a week, the total would not be correct.

 

[BVHis]

Thank you ALL for your replies! Your input was extremely helpful!

Matt

 

[Roger Govier]

You're quite right, John, my argument is flawed.
Your's, and the other solutions posted will solve the OP's problem
without the error that mine would potentially have had.