#N/A value is returned

[Guest]

I am looking for a number in a column and the result I want is either 0 or 1.

if number is there i want 1 and if not 0.

I am trying with vlookup function and it is not working.

Can anybody help please.

Regards
sai.

 

[Peo Sjoblom]

=--ISNUMBER(MATCH(A1,B1:B10,0))

 

[Guest]

Assume source numbers are running in A1 down,
and you have listed the numbers to be checked in B1 down

Place in C1:
=IF(B1="","",--ISNUMBER(MATCH(B1,A:A,0)))
Copy down as far as required.

 

[Guest]

I sloved it. found the solution from one of the posts.

thanks.

 

[Guest]

Maybe

=IF(ISNA(VLOOKUP(B1,A:A,1,FALSE)),0,1)

Vaya con Dios,
Chuck, CABGx3

 

[PCLIVE]

One way:

=IF(COUNTIF(A:A,35)>0,1,0)

Note, 35 is the number to be looked for. Change as needed or use a cell
reference =IF(COUNTIF(A:A,A2)>0,1,0)

HTH,
Paul

 

[PCLIVE]

Ok...So what solution did you go with?

I sloved it. found the solution from one of the posts.

thanks.

 

[Dave Thomas]

Assuming the number you're looking for is in A1 and your range of values is
in B1 through B10, in any order, then this will work:
=IF(ISNA(MATCH(A1,B1:B10,0)),0,1)

If the number in A1 matches exactly one of the numbers in B1 through B10
the MATCH function will return the relative position of the number, 1
through 10, in this case or the error value #N/A if the number in A1 is not
found in B1 through B10. As MATCH in this example is looking for an exact
match as specified by the third parameter in the MATCH function being 0, the
numbers in B1 though B10 may be in any order and there may be duplicate
numbers. If the number in A1 is one of the duplicates, MATCH will return the
relative position of the first duplicate.