Max rows reached?

[devan]

I'm trying to import the results from a test that I have
run. The results have 500000 data points and excel will
only let my import 65536 of them. Is there a way around
this or should I be looking for another application to
solve this?

Thanks,
Devan

 

[Frank Kabel]

Hi
no this is the maximum for one sheet.

 

[Bernie Deitrick]

Devan,

Try the macro below.

HTH,
Bernie
MS Excel MVP

Sub LargeFileImport()
'Dimension Variables
Dim ResultStr As String
Dim FileName As String
Dim FileNum As Integer
Dim Counter As Double
'Ask User for File's Name
FileName = Application.GetOpenFilename
'Check for no entry
If FileName = "" Then End
'Get Next Available File Handle Number
FileNum = FreeFile()
'Open Text File For Input
Open FileName For Input As #FileNum
'Turn Screen Updating Off
Application.ScreenUpdating = False
'Create A New WorkBook With One Worksheet In It
Workbooks.Add Template:=xlWorksheet
'Set The Counter to 1
Counter = 1
'Loop Until the End Of File Is Reached
Do While Seek(FileNum) <= LOF(FileNum)
'Display Importing Row Number On Status Bar
Application.StatusBar = "Importing Row " & _
Counter & " of text file " & FileName
'Store One Line Of Text From File To Variable
Line Input #FileNum, ResultStr
'Store Variable Data Into Active Cell
If Left(ResultStr, 1) = "=" Then
ActiveCell.Value = "'" & ResultStr
Else
ActiveCell.Value = ResultStr
End If
'For xl95 change 65536 to 16384
If ActiveCell.Row = 65536 Then
'If On The Last Row Then Add A New Sheet
ActiveWorkbook.Sheets.Add
Else
'If Not The Last Row Then Go One Cell Down
ActiveCell.Offset(1, 0).Select
End If
'Increment the Counter By 1
Counter = Counter + 1
'Start Again At Top Of 'Do While' Statement
Loop
'Close The Open Text File
Close
'Remove Message From Status Bar
Application.StatusBar = False
End Sub

 

[Guest]

Thanks Bernie that should do nicely once I add in the
formatting for my data.

Devan

 

[Myrna Larson]

Depending on what the data consists of (just 500,000 numbers?) you might be
able to use Excel by importing the data with Bernie's macro and putting it in
multiple columns or multiple worksheets.

But if there are several pieces of information for each data point, and you
want to do calculations and/or summarize the results, I suggest you might want
to use a database application for this. Once you have the data in Access, you
can use it's query methods to extract data, and you can create pivot tables in
Excel in which the datasource is an Access database.