Match Last Occurrence of Numeric Value and Count BACK to Previous

[Sam via OfficeKB.com]

Hi All,

I wish to locate the LAST occurrence of a numerical value and Count BACK to
the PREVIOUS time it appeared (counting the number of Rows between the Last
and the Previous occurrence) and have that POSITION or COUNT Returned from
within an 8 Column Dynamic Range called "Data".

Name Refers To Box: Data
=OFFSET(Actual!$C$2,0,0,COUNT(Actual!$C:$C),8)

I've received help with similar scenarios but I cannot return the correct
answer.

Thanks
Sam

 

[Domenic]

If the numerical value will never appear more than once in any row,
try...

=SUM(LARGE(IF(Data=A1,ROW(Data)-MIN(ROW(Data))+1),{1,2})*{1,-1})-1

Otherwise, try...

=SUM(LARGE(IF(MMULT(--(Data=A1),TRANSPOSE(COLUMN(Data)^0)),ROW(Data)-MIN(
ROW(Data))+1),{1,2})*{1,-1})-1

....where A1 contains the numerical value of interest. Note that both
formulas need to be confirmed with CONTROL+SHIFT+ENTER.

Hope this helps!

 

[rsenn]

I've posted a small file for you. This small file shows how to get th
row numbers of the last and 2nd last occurances of numbers in a column
It uses 3 columns other than the data column, but if you want you ca
merge the formulas.

http://www.anywhereenterprises.com:80/1/1/a?a=dF&p=sOWqqzY5isOWOAApQZOAAY5

 

[Sam via OfficeKB.com]

Hi Domenic,

Thank you very much indeed; that worked Great.

If the numerical value will never appear more than once in any row,
try...

...where A1 contains the numerical value of interest. Note that both
formulas need to be confirmed with CONTROL+SHIFT+ENTER.

Cheers,
Sam

If the numerical value will never appear more than once in any row,
try...

=SUM(LARGE(IF(Data=A1,ROW(Data)-MIN(ROW(Data))+1),{1,2})*{1,-1})-1

Otherwise, try...

=SUM(LARGE(IF(MMULT(--(Data=A1),TRANSPOSE(COLUMN(Data)^0)),ROW(Data)-MIN(
ROW(Data))+1),{1,2})*{1,-1})-1

...where A1 contains the numerical value of interest. Note that both
formulas need to be confirmed with CONTROL+SHIFT+ENTER.

Hope this helps!

Hi All,

[quoted text clipped - 11 lines]

Thanks
Sam

 

[Sam via OfficeKB.com]

Hi rsenn,

Thank you for providing a sample file, it was very helpful.

Cheers,
Sam