lookup using two columns

[john]

Hi, hope someone can help.

sheet 1
column a - date
column b - day
column c - shift number 1200 to 1273 occurs in any order with 2
variable rest days every week
eg
sun rest
mon 1273
tue 1200
wed 1234
thu 1200
fri rest
sat 1274
column d - cash

sheet 2
column a - shift number 1200 to 1273, row 2 = 1200, row 3 1201, row 4
1202 etc
column b - sun
column c - mon
column d - tue etc

is there a way to look up in sheet 1 the shift number and day and then
place the cash value into
its respective place in sheet 2.

many thanks
john

 

[Dave Peterson]

Saved from a previous post:

If you want exact matches for just two columns (and return a value from a
third), you could use:

=index(othersheet!$c$1:$c$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100),0))

(all in one cell)

This is an array formula. Hit ctrl-shift-enter instead of enter. If you do it
correctly, excel will wrap curly brackets {} around your formula. (don't type
them yourself.)

Adjust the range to match--but you can only use the whole column in xl2007.

This returns the value in othersheet column C when column A and B (of
othersheet) match A2 and B2 of the sheet with the formula.

And you can add more conditions by just adding more stuff to that product
portion of the formula:

=index(othersheet!$d$1:$d$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100)
*(c2=othersheet!$c$1:$c$100),0))

============
If there is only one match and you're bringing back a number (or 0 if there is
no match for all the criteria), you can use:

=sumproduct(--(othersheet!a1:a10=a1),
--(othersheet!b1:b10=b1),
(othersheet!c1:c10))

Adjust the ranges to match--but you can't use whole columns (except in xl2007).

=sumproduct() likes to work with numbers. The -- stuff changes trues and falses
to 1's and 0's.

Bob Phillips explains =sumproduct() in much more detail here:
http://www.xldynamic.com/source/xld.SUMPRODUCT.html

And J.E. McGimpsey has some notes at:
http://mcgimpsey.com/excel/formulae/doubleneg.html

 

[john]

Saved from a previous post:

If you want exact matches for just two columns (and return a value from a
third), you could use:

=index(othersheet!$c$1:$c$100,
   match(1,(a2=othersheet!$a$1:$a$100)
          *(b2=othersheet!$b$1:$b$100),0))

(all in one cell)

This is an array formula.  Hit ctrl-shift-enter instead of enter.  Ifyou do it
correctly, excel will wrap curly brackets {} around your formula.  (don't type
them yourself.)

Adjust the range to match--but you can only use the whole column in xl2007.

This returns the value in othersheet column C when column A and B (of
othersheet) match A2 and B2 of the sheet with the formula.

And you can add more conditions by just adding more stuff to that product
portion of the formula:

=index(othersheet!$d$1:$d$100,
   match(1,(a2=othersheet!$a$1:$a$100)
          *(b2=othersheet!$b$1:$b$100)
          *(c2=othersheet!$c$1:$c$100),0))

============
If there is only one match and you're bringing back a number (or 0 if there is
no match for all the criteria), you can use:

=sumproduct(--(othersheet!a1:a10=a1),
            --(othersheet!b1:b10=b1),
              (othersheet!c1:c10))

Adjust the ranges to match--but you can't use whole columns (except in xl2007).

=sumproduct() likes to work with numbers.  The -- stuff changes truesand falses
to 1's and 0's.

Bob Phillips explains =sumproduct() in much more detail here:http://www..xldynamic.com/source/xld.SUMPRODUCT.html

And J.E. McGimpsey has some notes at:http://mcgimpsey.com/excel/formulae/doubleneg.html










--

Dave Peterson- Hide quoted text -

- Show quoted text -

thanks for a speedy reply Dave.

looks as though this will work.

john

 

[Shane Devenshire]

Hi,

In 2003 you can use:

=SUMPRODUCT(--(Sheet3!$C$2:$C$12=$A2),--(Sheet3!$B$2:$B$12=B$1),(Sheet3!$D$2:$D$12))

In 2007 you can use:

=SUMIFS(Sheet3!$D$2:$D$12,Sheet3!$C$2:$C$12,$A2,Sheet3!$B$2:$B$12,B$1)

In both cases the code starts in A2 and goes down and the day of the week
starts in B1 and goes to the right.

 

[john]

Hi,

In 2003 you can use:

=SUMPRODUCT(--(Sheet3!$C$2:$C$12=$A2),--(Sheet3!$B$2:$B$12=B$1),(Sheet3!$D$­2:$D$12))

In 2007 you can use:

=SUMIFS(Sheet3!$D$2:$D$12,Sheet3!$C$2:$C$12,$A2,Sheet3!$B$2:$B$12,B$1)

In both cases the code starts in A2 and goes down and the day of the week
starts in B1 and goes to the right.

--
If this helps, please click the Yes button.

Cheers,
Shane Devenshire









- Show quoted text -

thanks Shane

will give your version a try as well