Last Record Error

[Arturo]

I am using the following code in the Timer Event.

Private Sub Form_Timer()
DoCmd.GoToRecord , , acNext
End Sub

When I get to the last record, how do I get it to return to the first record
instead of gettng the error message "You can't go to the specific record?"

Thank you.

 

[Ken Sheridan]

Trap and handle the error like so:

Const NOMORERECORDS = 2105

On Error Resume Next
DoCmd.GoToRecord , , acNext
Select Case Err.Number
Case 0
' no error
Case NOMORERECORDS
' go to first record
DoCmd.GoToRecord , , acFirst
Case Else
' unknown error
MsgBox Err.Description, vbExclamation, "Error"
End Select

Ken Sheridan
Stafford, England

 

[Dirk Goldgar]

(re-posting, as my original reply hasn't appeared)

I am using the following code in the Timer Event.

Private Sub Form_Timer()
DoCmd.GoToRecord , , acNext
End Sub

When I get to the last record, how do I get it to return to the first
record
instead of gettng the error message "You can't go to the specific record?"

Thank you.

I don't know whether your form allows additions or not, so the code below
allows for the possibility that it doesn't. It does assume that you don't
want to show the blank "new record", if the form allows additions/

'----- start of code -----
Private Sub Form_Timer()

On Error GoTo Err_Handler

DoCmd.GoToRecord , , acNext

If Me.NewRecord Then
DoCmd.GoToRecord , , acFirst
End If

Exit_Point:
Exit Sub

Err_Handler:
If Err.Number = 2105 Then
DoCmd.GoToRecord , , acFirst
Else
MsgBox Err.Description, vbExclamation, "Error " & Err.Number
End If
Resume Exit_Point

End Sub
'----- end of code -----

 

[Arturo]

Both options worked great. Thanks.

I don't know whether your form allows additions or not, so the code below
allows for the possibility that it doesn't. It does assume that you don't
want to show the blank "new record", if the form allows additions/

'----- start of code -----
Private Sub Form_Timer()

On Error GoTo Err_Handler

DoCmd.GoToRecord , , acNext

If Me.NewRecord Then
DoCmd.GoToRecord , , acFirst
End If

Exit_Point:
Exit Sub

Err_Handler:
If Err.Number = 2105 Then
DoCmd.GoToRecord , , acFirst
Else
MsgBox Err.Description, vbExclamation, "Error " & Err.Number
End If
Resume Exit_Point

End Sub
'----- end of code -----


--
Dirk Goldgar, MS Access MVP
www.datagnostics.com

(please reply to the newsgroup)