ISNA Formula returning "False" instead of value

[Picman]

i wrote this ISNA Formula

=IF(ISNA(VLOOKUP($A2,Specialists!$A$2:$E$93,2,FALSE)),VLOOKUP($A2,Specialists!$A$2:$E$93,2,FALSE))

and it is returning "False" instead of value. Can anyone help

 

[Shane Devenshire]

Hi,


1. N/A - If means it didn't find and exact match for A2 in columa A on the
second sheet.

2. If you are going to use ISNA Change the formula to

=IF(ISNA(VLOOKUP($A2,Specialists!$A$2:$E$93,2,FALSE)),"",VLOOKUP($A2,Specialists!$A$2:$E$93,2,FALSE))

 

[Jacob Skaria]

If this is returning error return blank and if not vlookup...

(all in one line)

=IF(
ISNA(VLOOKUP($A2,Specialists!$A$2:$E$93,2,FALSE)),
"",
VLOOKUP($A2,Specialists!$A$2:$E$93,2,FALSE))

If this post helps click Yes

 

[T. Valko]

You're missing the value_if_true argument for when ISNA is true.

Try this:

=IF(ISNA(VLOOKUP($A2,Specialists!$A$2:$E$93,2,0)),"",VLOOKUP($A2,Specialists!$A$2:$E$93,2,0))

A possible alternative:

=IF(COUNTIF(Specialists!$A$2:$A$93,$A2),VLOOKUP($A2,Specialists!$A$2:$E$93,2,0),"")

If you're using Excel 2007:

=IFERROR(VLOOKUP($A2,Specialists!$A$2:$E$93,2,0),"")

 

[Picman]

Thanks guys, all of your suggestions worked. Once again this is the place for
answers, great job!!!