insert file name

[Mark]

Hi,
Is there a way to program a cell to see and display the current name
of it's Excel file? Similar to the option displaying it in the header
or footer, I would like to display the file name in a cell of the
spreadsheet itself.
Any help would be appreciated.
Thanks in advance,
Mark

 

[Bob Tarburton]

Mark

Filename>
=MID(CELL("filename",A1),FIND("[",CELL("filename",A1))+1,(FIND("]",CELL("filename",A1))+1)-FIND("[",CELL("filename",A1))-2)

Sheet name>
=MID(CELL("filename",A1),FIND("]",CELL("filename",A1),1)+1,255)

Full Address>
=CELL("filename",A1)

Bob

 

[Guest]

=CELL("filename")

 

[Bob Phillips]

Mark,

Take a look at http://www.xldynamic.com/source/xld.xlFAQ0002.html

--

HTH

RP
(remove nothere from the email address if mailing direct)

 

[Bob Tarburton]

=CELL("filename")

Careful, if you don't use a cell reference on the sheet this formula
will show the path/file/sheet you were on when you last recalculated.
Also, switching back to the sheet or printing will not automatically
recalculate.

 

[Guest]

Excellent point!

Careful, if you don't use a cell reference on the sheet this formula
will show the path/file/sheet you were on when you last recalculated.
Also, switching back to the sheet or printing will not automatically
recalculate.