Insert a column with it's own delete button?

[Casey]

Good Morning,
I have a routine for inserting a copy of another column. The sheet wil
eventually need to be protected before others in my office can use it
so what I would like to do is to create a delete command button "tied
to the newly created column, so people can add and delete columns a
they need to. But, I have never created a control with code and I nee
some help. If its possible, the button should be placed in the 5th ro
of the column.

Here is my column create code:

Option Explicit

Sub AddMatnonPercent()
Dim MatNON As Range
Dim SCol As Integer
SCol = Range("MatNON").Column + 1
Range("MatNON").Copy
Columns(SCol).Select
Selection.Insert Shift:=xlToRight
Cells(7, SCol).ClearContents
Cells(7, SCol).Select
Application.CutCopyMode = False
End Su

 

[Guest]

Sub AddMatnonPercent()
Dim MatNON As Range
Dim SCol As Integer
Dim btn As Button
SCol = Range("MatNON").Column + 1
Range("MatNON").Copy
Columns(SCol).Select
Selection.Insert Shift:=xlToRight
Cells(7, SCol).ClearContents
Cells(7, SCol).Select
Application.CutCopyMode = False
With Cells(1, SCol)
Set btn = ActiveSheet.Buttons.Add(Left:=.Left, _
Top:=.Top, Width:=.Width, Height:=.Height)
End With
btn.Caption = "Delete me"
btn.OnAction = "Btn_Click"
End Sub

Sub Btn_click()
Dim sName As String
Dim btn As Button
sName = Application.Caller
Set btn = ActiveSheet.Buttons(sName)
btn.TopLeftCell.EntireColumn.Delete
btn.Delete
End Sub

 

[Casey]

Tom,
Brilliant! Exactly what I needed. Thank you so much for the help