Importing too much data...

[Mike]

I'm trying to import a large (200,000+ entries) text file into Excel.
I will get the message saying that the file contains more data than will fit
in a single worksheet & to get it all, go to another sheet & I can exclude
data already imported, but I never see that option?!? I've also tried
telling it to start at row 65537, but it says invalid integer.
Any suggestions?
Thanks-

 

[Bernie Deitrick]

Mike,

Below is the standard large file import macro.

HTH,
Bernie
MS Excel MVP

Sub LargeFileImport()
'Dimension Variables
Dim ResultStr As String
Dim FileName As String
Dim FileNum As Integer
Dim Counter As Double
'Ask User for File's Name
FileName = Application.GetOpenFilename
'Check for no entry
If FileName = "" Then End
'Get Next Available File Handle Number
FileNum = FreeFile()
'Open Text File For Input
Open FileName For Input As #FileNum
'Turn Screen Updating Off
Application.ScreenUpdating = False
'Create A New WorkBook With One Worksheet In It
Workbooks.Add Template:=xlWorksheet
'Set The Counter to 1
Counter = 1
'Loop Until the End Of File Is Reached
Do While Seek(FileNum) <= LOF(FileNum)
'Display Importing Row Number On Status Bar
Application.StatusBar = "Importing Row " & _
Counter & " of text file " & FileName
'Store One Line Of Text From File To Variable
Line Input #FileNum, ResultStr
'Store Variable Data Into Active Cell
If Left(ResultStr, 1) = "=" Then
ActiveCell.Value = "'" & ResultStr
Else
ActiveCell.Value = ResultStr
End If
'For xl95 change 65536 to 16384
If ActiveCell.Row = 65536 Then
'If On The Last Row Then Add A New Sheet
ActiveWorkbook.Sheets.Add
Else
'If Not The Last Row Then Go One Cell Down
ActiveCell.Offset(1, 0).Select
End If
'Increment the Counter By 1
Counter = Counter + 1
'Start Again At Top Of 'Do While' Statement
Loop
'Close The Open Text File
Close
'Remove Message From Status Bar
Application.StatusBar = False
End Sub

 

[Dave Peterson]

Another option may be to use a text editor to break it into manageable pieces.
Then import those into separate workbooks/worksheets.

 

[Amedee Van Gasse]

I'm trying to import a large (200,000+ entries) text file into Excel.
I will get the message saying that the file contains more data than
will fit in a single worksheet & to get it all, go to another sheet &
I can exclude data already imported, but I never see that option?!?
I've also tried telling it to start at row 65537, but it says invalid
integer. Any suggestions?
Thanks-

Yet another option is importing the data in an Access database, and use
a database query in Excel to import only the data you need, keeping the
resultset below 65K records.
I cannot imagine you really, really need all 200000+ entries at the
same time.

And another option is to skip Access, and use a query directly on the
textfile, again keeping the resultset below 65K.


PS: 65K (2^16) rows is a built-in limitation of Excel, just like 256
(2^8) columns.

--
Amedee Van Gasse

To top-post is human, to bottom-post and snip is sublime.

Dit bericht is geplaatst in een nieuwsgroep. Post je evt antwoord of
vervolgvraag graag in dezelfde thread in de nieuwsgroep a.u.b.

 

[Bill Sharpe]

Try Quattro Pro, which can handle 1,000,000 rows.
However, as others have mentioned, do you really need 200,000+ records
at once? If so, a database approach may be preferred.

Bill

I'm trying to import a large (200,000+ entries) text file into Excel.
I will get the message saying that the file contains more data than will
fit
in a single worksheet & to get it all, go to another sheet & I can
exclude
data already imported, but I never see that option?!? I've also tried
telling it to start at row 65537, but it says invalid integer.
Any suggestions?
Thanks-