IF function

[Guest]

Can someone tell me why this formula gives me an error message? It works for
0 thru 5 but when i add the sixth or more it errors out.
Thanks, John

=IF(10-COUNTBLANK(F3:O3)=0,TRUNC(SUM(F3:O3)+C3),
IF(10-COUNTBLANK(F3:O3)=1,TRUNC((SUM(F3:O3)+C3*20)/30),
IF(10-COUNTBLANK(F3:O3)=2,TRUNC((SUM(F3:O3)+C3*10)/30),
IF(10-COUNTBLANK(F3:O3)=3,TRUNC(SUM(F3:O3)/30),
IF(10-COUNTBLANK(F3:O3)=4,TRUNC(SUM(F3:O3)/40),
IF(10-COUNTBLANK(F3:O3)=5,TRUNC(SUM(F3:O3)/50),
IF(10-COUNTBLANK(F3:O3)=6,TRUNC(SUM(F3:O3)/60,""))))))

 

[Guest]

There is a limit of 7 nested if functions and you have reached it.

 

[Guest]

maybe

=IF(AND(COUNTBLANK(F3:O3)>3,COUNTBLANK(F3:O3)<8),TRUNC(SUM(F3:O3)/(10*(10-COUNTBLANK(F3:O3)))),IF(10-COUNTBLANK(F3:O3)=0,TRUNC(SUM(F3:O3)+C3),IF(10-COUNTBLANK(F3:O3)=1,TRUNC((SUM(F3:O3)+C3*20)/30),IF(10-COUNTBLANK(F3:O3)=2,TRUNC((SUM(F3:O3)+C3*10)/30),""))))

 

[Guest]

I actually have to continue up to IF 10-COUNTBLANK =10

 

[Guest]

If the formulas for 7 to 10 follow those of 3 to 6 then Duke's solution would
work with a minor modification.

What are those for 7 to 10?

 

[Guest]

Each cell in F3:O3 represents a total of 10 games of bowling/day. F3:J3
would be 5 days or 50 games for the month of Nov. K3:O3 would be 5 days
or 50 games in Dec. All these games may or may not be bowled. I'm good for
the first 5 IF's but just need to continue it to 10 IF's, F3:O3.

 

[Guest]

what i wanted to know was:

IF(10-COUNTBLANK(F3:O3)=7,TRUNC(SUM(F3:O3)/70?
IF(10-COUNTBLANK(F3:O3)=8,TRUNC(SUM(F3:O3)/80?
?
?

 

[Arvi Laanemets]

Hi

=TRUNC((SUM(F3:O3)+CHOOSE(11-COUNTBLANK(F3:O3),C3,C3*20,C3*10,0,0,0,0,0,0,0,0))/CHOOSE(11-COUNTBLANK(F3:O3),1,30,30,30,40,50,60,70,80,90,100))

(There can be up to 28 options in CHOOSE function)

 

[Guest]

Yes, that is correct

what i wanted to know was:

IF(10-COUNTBLANK(F3:O3)=7,TRUNC(SUM(F3:O3)/70?
IF(10-COUNTBLANK(F3:O3)=8,TRUNC(SUM(F3:O3)/80?
?
?

 

[Guest]

thank you

Hi

=TRUNC((SUM(F3:O3)+CHOOSE(11-COUNTBLANK(F3:O3),C3,C3*20,C3*10,0,0,0,0,0,0,0,0))/CHOOSE(11-COUNTBLANK(F3:O3),1,30,30,30,40,50,60,70,80,90,100))

(There can be up to 28 options in CHOOSE function)

 

[Guest]

Now, the next step, if I extend that to 15 cells (F2:T2), will that formula
work also? Of course I'll change 10-COUNTBLANK to 15-COUNTBLANK