=IF(D43>=45*D43<=87,"5.00","0.00")

[Guest]

I'm trying to get a formula to be between two numbers. Is my * my problem

 

[Gary]

I'm trying to get a formula to be between two numbers. Is my * my problem

Try

=if(and(D43>=45,D43<=87),"5.00","0.00")

is this what u need?

 

[Biff]

I'm trying to get a formula to be between two numbers. Is my * my problem
=IF(D43>=45*D43<=87,"5.00","0.00")

Try this:

=AND(D43>=45,D43<=87)*5

Format as NUMBER 2 decimal places

Biff

 

[Guest]

That work and i thought i could finsh the restbut can't could you look at
this please

=IF(B44>14*B44<24*D44>44*D44<88*F44>999*F44<1276,"$75.00",IF(B44>14*B44<24*D44>44*D44<88,"$37.50","$0.00"))

 

[Biff]

That work and i thought i could finsh the restbut can't could you look at
this please

=IF(B44>14*B44<24*D44>44*D44<88*F44>999*F44<1276,"$75.00",IF(B44>14*B44<24*D44>44*D44<88,"$37.50","$0.00"))

Try this:

=IF(AND(B44>14,B44<24,D44>44,D44<88,F44>999,F44<1276),75,IF(AND(B44>14,B44<24,D44>44,D44<88),37.5,0))

Biff

 

[Guest]

Gary,
this works but need to and two more cells and ranges to this formula could
this be done

 

[Guest]

Gary,
This works for but could i e-mail you my sheet and you may understand better
than i can explain it

 

[Gary]

sure..send it to (e-mail address removed)

Gary,
This works for but could i e-mail you my sheet and you may understand
better
than i can explain it

 

[Guest]

I sent if you have any ? you can e-mail me

sure..send it to (e-mail address removed)

 

[Gary]

I got the file but can u just write in words what u need.

 

[edwardpestian]

Try this. Enter as an array formula


Code:

 

[Gary]

Hi MIke, this is what i think u need and hope this would do what u r looking
for.

=IF(AND(B43>=14.1,B43<=23,D43>=45,D43<=87,E43>=1000,E43<=1275),"$75.00",IF(OR(AND(D43>=45,D43<=87,E43>=1000,E43<=1275),AND(B43>=14.1,B43<=23,D43>=45,D43<=87)),"$37.5","0.00"))
"edwardpestian" <[email protected]>
wrote in message
news:[email protected]...

 

[Gary]

Sorry, I entered E instead of F

this is working fine now.
=IF(AND(B43>=14.1,B43<=23,D43>=45,D43<=87,F43>=1000,F43<=1275),"$75.00",IF(OR(AND(D43>=45,D43<=87,F43>=1000,F43<=1275),AND(B43>=14.1,B43<=23,D43>=45,D43<=87)),"$37.5","0.00"))

 

[Biff]

Try this. Enter as an array formula
Code:
=IF((B44>14)*(B44<24)*(D44>44)*(D44<88)*(F44>999)*(F44<1276),"
$75.00",IF((B44>14)*(B44<24)*(D44>44)*(D44<88),"$37.50","$0.00"))

No need to array enter, just enter normally.

I'd be willing to bet a huge amount of money that the OP intends the result
to be NUMERIC, so:

=IF((B44>14)*(B44<24)*(D44>44)*(D44<88)*(F44>999)*(F44<1276),75,IF((B44>14)*(B44<24)*(D44>44)*(D44<88),37.5,0))

Then just format as CURRENCY 2 decimal places.

Biff