I think I know how to ask this sumproduct question now:

[Gina]

This is a sumproduct formula I have worked out to count the number of
recordable events that occurred within a date range.

=SUMPRODUCT((Data!A$2:A$2550>=ListValues!A2)*(Data!A$2:A$2550<ListValues!B2)*(Data!H$2:H$2550="Recordable"))

Now what I am trying to do is capture the cost of these recordable events
(adding another array to sumproduct). These costs are located in cells
Data!K$2:K$2550.

I have not been able to get this $ total by using sumproduct. Somehow I
keep screwing up. The only way I have been able to get this total is by
using conditional sum- but by doing this I am not able to "pull" these
calculations to adjacent cells- and I'm summarizing 20 years of data, so with
each calculation only giving me a month-total, I could be entering the next 3
days if I don't figure this out.

So here's the conditional-sum formula that gives the total- but that I have
to enter each time:

=SUM(IF(Data!$A$2:$A$2500>=ListValues!A2,IF(Data!$H$2:$H$2500=A19,IF(Data!$A$2:$A$2500<ListValues!B2,Data!$K$2:$K$2500,0),0),0))

Is it possible to get to this total with SumProduct?

 

[PCLIVE]

Maybe this:

=SUMPRODUCT((Data!A$2:A$2550>=ListValues!A2)*(Data!A$2:A$2550<ListValues!B2)*(Data!H$2:H$2550="Recordable"),Data!K$2:K$2550)

HTH,
Paul

 

[T. Valko]

Try this:

=SUMPRODUCT(--(Data!A$2:A$2550>=ListValues!A2),--(Data!A$2:A$2550<ListValues!B2),--(Data!H$2:H$2550="Recordable"),Data!K$2:K$2550)

 

[M Kan]

Or

=SUMPRODUCT(--(Data!A$2:A$2550>=ListValues!A2),
--(Data!A$2:A$2550<ListValues!B2),--(Data!H$2:H$2550="Recordable"),Data!K$2:K$2550)

You can further replace "recordable" with a cell reference tied to a drop
down to make this even more flexible.

 

[Gina]

You guys are the absolute best. I can't even begin to tell you how relieved
I am that this has worked.

Thank you so much.

 

[Elkar]

Try this:

=SUMPRODUCT(--(Data!A$2:A$2550>=ListValues!A2),--(Data!A$2:A$2550<ListValues!B2),--(Data!H$2:H$2550="Recordable"),Data!K$2:K$2550)

HTH
Elkar