See
http://www.gmayor.com/individual_merge_letters.htm
The following will split a document by page into the folder selected in the
macro into consecutively numbered files. The macro creates the new documents
based on the normal template.
Sub SplitByPage()
Dim sPath As String
Dim sName As String
Dim Letters As Long
Dim rDoc As Document
Dim rLoad As String
Dim fDialog As FileDialog
Set fDialog = Application.FileDialog(msoFileDialogFolderPicker)
With fDialog
.Title = "Select Folder To Save Split Files and click OK"
.AllowMultiSelect = False
.InitialView = msoFileDialogViewList
If .Show <> -1 Then
MsgBox "Cancelled By User"
Exit Sub
End If
DocDir = fDialog.SelectedItems.Item(1)
If Right(DocDir, 1) <> "\" Then DocDir = DocDir + "\"
End With
Set rDoc = ActiveDocument
With rDoc
If Len(.Path) = 0 Then
.Save
End If
If UCase(Right(.name, 1)) = "X" Then
sName = Left(.name, Len(.name) - 5)
Else
sName = Left(.name, Len(.name) - 4)
End If
rLoad = rDoc.FullName
End With
With Selection
.EndKey Unit:=wdStory
Letters = .Information(wdActiveEndPageNumber)
.HomeKey Unit:=wdStory
End With
Counter = 1
While Counter < Letters + 1
Application.ScreenUpdating = False
docName = DocDir _
& sName & Chr(32) & _
LTrim$(Str$(Counter)) & ".doc"
ActiveDocument.Bookmarks("\page").Range.Cut
Documents.Add
With Selection
.Paste
.EndKey Unit:=wdStory
.MoveLeft Unit:=wdCharacter, Count:=1
.Delete Unit:=wdCharacter, Count:=1
End With
ActiveDocument.SaveAs FileName:=docName, _
FileFormat:=wdFormatDocument
ActiveWindow.Close
Counter = Counter + 1
Application.ScreenUpdating = True
Wend
rDoc.Close wdDoNotSaveChanges
Documents.Open rLoad
End Sub
--
<>>< ><<> ><<> <>>< ><<> <>>< <>><<>
Graham Mayor - Word MVP
My web site
www.gmayor.com
<>>< ><<> ><<> <>>< ><<> <>>< <>><<>
