How to count several non-adjacent cells

[Guest]

Would like your help for this one:

I have a large sheet with data sorted in columns split for 2004 and 2005
(see below). I want to count the numbers of cells for e.g. 2004 that are
below 3% or above 70% (answers should be 1), however the formula does not
work and I have no idea why.

Appreciate if a expert could have a look at this. hope I explained it good
enough

Thnks in advance, RMF

A B C D E F
1 2004 2005 2004 2005 2004 2005
2 40.00% 80.0% 90.0% 40.0% 50% 60%

=SUM(IF(((A2,C2,E2)<0.03)+((A2,C2,E2)>0.7),1,0))

= #VALUE!

 

[Pete]

It looks like this should be an array formula - click in the formula
bar as if you were going to edit it and press CTRL SHIFT and ENTER at
the same time. Curly brackets will appear around the formula (you can
not type these yourself).

Pete

 

[topola]

Hi, that's simple:

Give ranges names (Insert>Name>Define)
A1:G1=years
A2:G2=values

This formula should do the work:
=SUM(IF(years=2004,IF(values<0.03,1,IF(values>0.7,1,0)),0))

This is an array formula i.e. use CTRL+SHIFT+ENTER when typed in.

 

[Cutter]

You say you want to count the cells that match but your attempte
formula uses sum. 2 very different things. I'll assume you actuall
want to count them so try this:

=SUMPRODUCT(--(A1:F1=2005),--(A2:F2>0.7))+SUMPRODUCT(--(A1:F1=2005),--(A2:F2<0.03)

 

[Peo Sjoblom]

If it is always every other row for 2004 use

=SUMPRODUCT((MOD(COLUMN(A2:F2),2)=1)*((A2:F2<0.03)+(A2:F2>0.7)))

for 2005 use

=SUMPRODUCT((MOD(COLUMN(A2:F2),2)=0)*((A2:F2<0.03)+(A2:F2>0.7)))

 

[Guest]

Hi RMF,

The If function returns a "text" value (i.e. True or False) and the plus
sign in your formula is asking Excel to "sum" a "text" value, therefore it
does not recognize it. From looking at your formula it looks like you want a
value of 1 to return in the cell if it meets the criteria and a value of 0 if
it doesn't. Assuming you will then sum the column to get the total number of
cells that meet the criteria. A very simple solution would be to do separate
If functions in two separate columns, one for >.03 and the other <.7
returning a value of 1 then summing the two columns.

Dont really consider myself an expert but HTH

AndreaSykes

 

[Peo Sjoblom]

There are several reasons that RMF's formula does not work but adding TRUE
or FALSE is not one of them, in fact calculations using TRUE or FALSE is the
whole idea behind array formulas

 

[Guest]

Thnks! Works fine!

RMF

 

[Pete]

That was my immediate reaction to the formula, but then I noticed that
the formula is adding either 1 or 0 so it is effectively counting.

Pete