how do I sum a column that has #NA as an answer to a lookup?

[Guest]

I am trying to add a column that has #NA as a result of using the Vlookup
function. I would like to add up the column that does not have #NA as an
answer.

 

[Pete_UK]

Change the cells with the vlookup formula in to this:

=IF(ISNA(your_formula),"",your_formula)

and copy down. The sum of this column should now work, but you could
change the "" in the middle to 0 (zero) if you prefer.

Hope this helps.

Pete

 

[Guest]

Hi Shreman,

Change your vlookup as-

=IF(ISERROR(<vlookup>),0,<vlookup>)

this will replace all the #N/A with 0 and your sum will work.

 

[Guest]

Best if you remove the #NA:

=if(ISNA(Vlookup),"",Vlookup)

or

=if(ISNA(Vlookup),0,Vlookup)

 

[Guest]

You want to avoid the NA's in the first place. Change your vlookups to
something like this...

if(countif(range, item) = 0, 0, vlookup(item, range, column, false))
or
if(isna(vlookup), 0, vlookup)

The first option is a bit more efficient but it is a bit more work to write...

 

[Peo Sjoblom]

=SUMIF(B2:B100,"<="&99^99)

will disregard any #N/A errors in B2:B100 although you might want to fix it
in the vlookup formulas instead by using IF(ISNA(Vlookup),"",Vlookup)

 

[Guest]

=SUMIF(A1:A6,"<>#N/A")

 

[iliace]

As an array formula (press Ctrl+Shift+Enter to confirm):

=SUM(IF(ISERROR(A1:A99),0,A1:A99))

Using error-checking in the lookup formula is a better approach, but
the above will work.

 

[Guest]

I like your equation. It is more general than just testing for #N/A.