getting macro to run

  • Thread starter Thread starter Guest
  • Start date Start date
G

Guest

hi,

i picked this up last week on this forum and have not been able to get it to
run. i can't get it to show up in the run macro dialog. does anyone have
sugestions as to how i can get this snippet to run? thanks--

Private Sub User(ByVal Target As Range)
Target.Interior.ColorIndex = 0
On Error Resume Next
Dim curComment As String
curComment = ""
curComment = Target.Comment.Text
If curComment <> "" Then curComment = curComment & Chr(10)
Target.AddComment
Target.Comment.Text Text:=curComment & _
ActiveWorkbook.Application.UserName & _
Chr(10) & " Rev. " & Format(Date, "yyyy-mm-dd ") & _
Format(Time, "hh:mm")
ActiveCell.Comment.Visible = False
'comment perhaps should be resized
End Sub
 
It won't show for two reasons, it is Private, and it has arguments.

Maybe this is what you want

Sub User()
Dim curComment As String
With ActiveCell

.Interior.ColorIndex = 0
On Error Resume Next
curComment = ""
curComment = .Comment.Text
If curComment <> "" Then curComment = curComment & Chr(10)
.AddComment
.Comment.Text Text:=curComment & _
ActiveWorkbook.Application.UserName & _
Chr(10) & " Rev. " & Format(Date, "yyyy-mm-dd ") & _
Format(Time, "hh:mm")
End With
End Sub


--
HTH

Bob

(there's no email, no snail mail, but somewhere should be gmail in my addy)
 
I pasted your sub in a standard module.

I also pasted:

Sub demo()
Call User(ActiveCell)
End Sub

in the same standard module.

back on the worksheet, I entered a comment in a cell, selected that cell and
ran the macro demo

The macro ran successfully and modified the comment to include my name and a
time/date marker.
 
Back
Top