Here's a way of doing it by a single formula in F1 and then copied

down.

To check that it works, though, put these simpler formulae in the

cells stated:

G1: =CHAR(65+MOD(INT((ROW()-1)/5/5/5/5/5),5))&"1"

H1: =CHAR(65+MOD(INT((ROW()-1)/5/5/5/5),5))&"2"

I1: =CHAR(65+MOD(INT((ROW()-1)/5/5/5),5))&"3"

J1: =CHAR(65+MOD(INT((ROW()-1)/5/5),5))&"4"

K1: =CHAR(65+MOD(INT((ROW()-1)/5),5))&"5"

L1: =CHAR(65+MOD(ROW()-1,5))&"6"

If you copy those down you will get this in the first few rows:

A1 A2 A3 A4 A5 A6

A1 A2 A3 A4 A5 B6

A1 A2 A3 A4 A5 C6

A1 A2 A3 A4 A5 D6

A1 A2 A3 A4 A5 E6

A1 A2 A3 A4 B5 A6

A1 A2 A3 A4 B5 B6

A1 A2 A3 A4 B5 C6

A1 A2 A3 A4 B5 D6

A1 A2 A3 A4 B5 E6

A1 A2 A3 A4 C5 A6

A1 A2 A3 A4 C5 B6

A1 A2 A3 A4 C5 C6

and if you copy all the way to row 15625 you will find all

combinations of the cell references.

So, all we need to do is to combine those into one formula and get

Excel to convert the strings into cell references. Put this in F1:

=INDIRECT(CHAR(65+MOD(INT((ROW()-1)/5/5/5/5/5),5))&"1")

+INDIRECT(CHAR(65+MOD(INT((ROW()-1)/5/5/5/5),5))&"2")

+INDIRECT(CHAR(65+MOD(INT((ROW()-1)/5/5/5),5))&"3")

+INDIRECT(CHAR(65+MOD(INT((ROW()-1)/5/5),5))&"4")

+INDIRECT(CHAR(65+MOD(INT((ROW()-1)/5),5))&"5")

+INDIRECT(CHAR(65+MOD((ROW()-1),5))&"6")

and then you can copy this down to F15625. You can delete columns G to

L.

Hope this helps.

Pete