Formula referring to another formula

[57Caddy]

Okay, now I have a more serious question. Say cell B5 equals 6 or greater,
then

=IF(C5>=17.5%,5,IF(C5>=16.25%,4,IF(C5>=14.25%,3,IF(C5>=13%,2,IF(C5>=0,1,"N/A")))))

and if B5 equals 5 then

=IF(C5>=16.5%,5,IF(C5>=15.25%,4,IF(C5>=13.25%,3,IF(C5>=12%,2,IF(C5>=0,1,"N/A")))))

and so on down to B5 equaling down to 1 or less.

How do I do this? Forgive me for being kind of a hack.

 

[Max]

Hazarding some thoughts here ..

Illustration in this sample:
http://www.freefilehosting.net/download/NDMzOTA=
Extracting values from a 2 way table.xls

First, set-up a 2-way reference table in say, H2:N7
with col B input values listed in I2:N2 (1-6)
and col C input values in H3:H7 (1-5)

Eg part of the table is shown below,
with col B values: 5, 6 only
(table is populated by inferring the values
from the 2 formulas in your post)

5 6
1 0 0
2 12% 13%
3 13.25% 14.25%
4 15.25% 16.25%
5 16.50% 17.50%

Then, with paired inputs for cols B and C assumed made in B5:C5 down

Place in D5:
=IF(COUNT(B5:C5)<2,"",INDEX($I$3:$N$7,MATCH(C5,$H$3:$H$7),MATCH(B5,$I$2:$N$2)))
Copy D5 down as far as required

 

[Max]

Think I mis-interpreted it earlier

Here's a revised sample to illustrate:
http://www.freefilehosting.net/download/NDM0NzY=
Extracting values from a 2 way table_1.xls

First, set-up the reference table in say, I2:N7
with col B input values listed in I2:N2 (1-6)
and the 5 percentages for each input within I3:N7

Eg part of the table is shown below,
with col B values: 5, 6 only
(values below the 5 & 6 are populated
by inferring from the 2 formulas in your post)

5 6
0 0
12% 13%
13.25% 14.25%
15.25% 16.25%
16.50% 17.50%

Then, with paired inputs for cols B and C assumed in B5:C5 down
place in D5:
=IF(COUNT(B5:C5)<2,"",MATCH(C5,OFFSET($H$3:$H$7,,MATCH(B5,$I$2:$N$2))))
Copy D5 down as far as required

If B5:C5 contains 6, 15%, D5 will return: 3
If B5:C5 contains 5, 13%, D5 will return: 2
and so on

---